[arch-commits] Commit in nginx-mod-echo/repos (2 files)

Giancarlo Razzolini grazzolini at archlinux.org
Thu May 9 15:15:16 UTC 2019


    Date: Thursday, May 9, 2019 @ 15:15:16
  Author: grazzolini
Revision: 464625

archrelease: copy trunk to community-staging-x86_64

Added:
  nginx-mod-echo/repos/community-staging-x86_64/
  nginx-mod-echo/repos/community-staging-x86_64/PKGBUILD
    (from rev 464624, nginx-mod-echo/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: nginx-mod-echo/repos/community-staging-x86_64/PKGBUILD (from rev 464624, nginx-mod-echo/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-09 15:15:16 UTC (rev 464625)
@@ -0,0 +1,39 @@
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgname=nginx-mod-echo
+pkgver=0.61
+pkgrel=6
+
+_modname="${pkgname#nginx-mod-}"
+_nginxver=1.16.0
+
+pkgdesc='Nginx module that provides directives "echo", "sleep", "time" and more'
+arch=('x86_64')
+depends=("nginx=$_nginxver")
+url="https://github.com/openresty/echo-nginx-module"
+license=('BSD')
+
+source=(
+	https://nginx.org/download/nginx-$_nginxver.tar.gz{,.asc}
+	https://github.com/openresty/$_modname-nginx-module/archive/v$pkgver/$_modname-$pkgver.tar.gz
+)
+validpgpkeys=(B0F4253373F8F6F510D42178520A9993A1C052F8) # Maxim Dounin <mdounin at mdounin.ru>
+sha256sums=('4fd376bad78797e7f18094a00f0f1088259326436b537eb5af69b01be2ca1345'
+            'SKIP'
+            '2e6a03032555f5da1bdff2ae96c96486f447da3da37c117e0f964ae0753d22aa')
+
+build() {
+	cd "$srcdir"/nginx-$_nginxver
+	./configure --with-compat --add-dynamic-module=../$_modname-nginx-module-$pkgver
+	make modules
+}
+
+package() {
+	install -Dm644 "$srcdir/"$_modname-nginx-module-$pkgver/LICENSE \
+	               "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+	cd "$srcdir"/nginx-$_nginxver/objs
+	for mod in *.so; do
+		install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
+	done
+}



More information about the arch-commits mailing list