[arch-commits] Commit in nginx-mod-modsecurity/repos (2 files)

Giancarlo Razzolini grazzolini at archlinux.org
Thu May 9 15:17:52 UTC 2019


    Date: Thursday, May 9, 2019 @ 15:17:51
  Author: grazzolini
Revision: 464636

archrelease: copy trunk to community-staging-x86_64

Added:
  nginx-mod-modsecurity/repos/community-staging-x86_64/
  nginx-mod-modsecurity/repos/community-staging-x86_64/PKGBUILD
    (from rev 464635, nginx-mod-modsecurity/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: nginx-mod-modsecurity/repos/community-staging-x86_64/PKGBUILD (from rev 464635, nginx-mod-modsecurity/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-09 15:17:51 UTC (rev 464636)
@@ -0,0 +1,37 @@
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgname=nginx-mod-modsecurity
+epoch=1
+pkgver=1.0.0
+pkgrel=5
+_nginxver=1.16.0
+
+pkgdesc='ModSecurity v3 Nginx Connector (module for nginx)'
+arch=('x86_64')
+depends=("nginx=$_nginxver" 'libmodsecurity')
+url="https://github.com/SpiderLabs/ModSecurity-nginx"
+license=('GPL3')
+
+source=(
+	https://nginx.org/download/nginx-$_nginxver.tar.gz{,.asc}
+	https://github.com/SpiderLabs/ModSecurity-nginx/releases/download/v$pkgver/modsecurity-nginx-v$pkgver.tar.gz{,.asc}
+)
+validpgpkeys=('B0F4253373F8F6F510D42178520A9993A1C052F8'  # Maxim Dounin <mdounin at mdounin.ru>
+              '190EFACCA1E9FA466A8ECD9CE6DFB08CE8B11277') # Felipe Zimmerle
+sha256sums=('4fd376bad78797e7f18094a00f0f1088259326436b537eb5af69b01be2ca1345'
+            'SKIP'
+            '06f78eb6d33833cc247257c4095c0ee528e80a61f1f52e1da5fdca5e464975a0'
+            'SKIP')
+
+build() {
+	cd "$srcdir"/nginx-$_nginxver
+	./configure --with-compat --add-dynamic-module=../modsecurity-nginx-v$pkgver
+	make modules
+}
+
+package() {
+	cd "$srcdir"/nginx-$_nginxver/objs
+	for mod in *.so; do
+		install -Dm755 $mod "$pkgdir/usr/lib/nginx/modules/$mod"
+	done
+}


More information about the arch-commits mailing list