[arch-commits] Commit in nginx-mod-srcache/repos (2 files)

Giancarlo Razzolini grazzolini at archlinux.org
Thu May 9 15:23:46 UTC 2019


    Date: Thursday, May 9, 2019 @ 15:23:40
  Author: grazzolini
Revision: 464663

archrelease: copy trunk to community-staging-x86_64

Added:
  nginx-mod-srcache/repos/community-staging-x86_64/
  nginx-mod-srcache/repos/community-staging-x86_64/PKGBUILD
    (from rev 464662, nginx-mod-srcache/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: nginx-mod-srcache/repos/community-staging-x86_64/PKGBUILD (from rev 464662, nginx-mod-srcache/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-09 15:23:40 UTC (rev 464663)
@@ -0,0 +1,39 @@
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgname=nginx-mod-srcache
+pkgver=0.31
+pkgrel=7
+
+_modname="${pkgname#nginx-mod-}"
+_nginxver=1.16.0
+
+pkgdesc='Nginx module for transparent subrequest-based caching layout for arbitrary locations'
+arch=('x86_64')
+depends=("nginx=$_nginxver")
+url="https://github.com/openresty/srcache-nginx-module"
+license=('BSD')
+
+source=(
+	https://nginx.org/download/nginx-$_nginxver.tar.gz{,.asc}
+	https://github.com/openresty/$_modname-nginx-module/archive/v$pkgver/$_modname-$pkgver.tar.gz
+)
+validpgpkeys=(B0F4253373F8F6F510D42178520A9993A1C052F8) # Maxim Dounin <mdounin at mdounin.ru>
+sha256sums=('4fd376bad78797e7f18094a00f0f1088259326436b537eb5af69b01be2ca1345'
+            'SKIP'
+            '3f9729e73a8340926fa9d9fc15707c2f287cd27b6a9fe42e83f660ca48a5972d')
+
+build() {
+	cd "$srcdir"/nginx-$_nginxver
+	./configure --with-compat --add-dynamic-module=../$_modname-nginx-module-$pkgver
+	make modules
+}
+
+package() {
+	cd "$srcdir"/nginx-$_nginxver/objs
+	for mod in *.so; do
+		install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
+	done
+
+	install -Dm644 "$srcdir"/$_modname-nginx-module-$pkgver/README.markdown \
+	               "$pkgdir"/usr/share/licenses/$pkgname/README.markdown
+}



More information about the arch-commits mailing list