[arch-commits] Commit in haskell-hedgehog/repos (2 files)

[Felix Yan]

    Date: Friday, May 10, 2019 @ 15:50:21
  Author: felixonmars
Revision: 464912

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hedgehog/repos/community-staging-x86_64/
  haskell-hedgehog/repos/community-staging-x86_64/PKGBUILD
    (from rev 464911, haskell-hedgehog/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-hedgehog/repos/community-staging-x86_64/PKGBUILD (from rev 464911, haskell-hedgehog/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-10 15:50:21 UTC (rev 464912)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hedgehog
+pkgname=haskell-hedgehog
+pkgver=0.6.1
+pkgrel=31
+pkgdesc="A modern property-based testing system"
+url="https://hedgehog.qa"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-async' 'haskell-concurrent-output'
+         'haskell-exceptions' 'haskell-lifted-async' 'haskell-mmorph' 'haskell-monad-control'
+         'haskell-pretty-show' 'haskell-primitive' 'haskell-random' 'haskell-resourcet'
+         'haskell-th-lift' 'haskell-transformers-base' 'haskell-wl-pprint-annotated')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('577989ee841426bec5af54d4e0c82623b184bc45addc3ae633e031bc51b2af1a459fbde8563d507d9883bd7714b3f7a887d906f3a30da18c9a6b8f22b5e3410f')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e 's/<.*1.8/<2/' -e 's/< *2.5/<3/' -e 's/< *2.14/<3/' $_hkgname.cabal
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}