[arch-commits] Commit in haskell-shelly/repos (2 files)

[Felix Yan]

    Date: Friday, May 10, 2019 @ 15:54:12
  Author: felixonmars
Revision: 464918

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-shelly/repos/community-staging-x86_64/
  haskell-shelly/repos/community-staging-x86_64/PKGBUILD
    (from rev 464917, haskell-shelly/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-shelly/repos/community-staging-x86_64/PKGBUILD (from rev 464917, haskell-shelly/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-10 15:54:12 UTC (rev 464918)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=shelly
+pkgname=haskell-shelly
+pkgver=1.8.1
+pkgrel=52
+pkgdesc="Shell-like (systems) programming in Haskell"
+url="https://github.com/yesodweb/Shelly.hs"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-unix-compat' 'haskell-system-filepath'
+         'haskell-system-fileio' 'haskell-monad-control' 'haskell-lifted-base'
+         'haskell-lifted-async' 'haskell-exceptions' 'haskell-enclosed-exceptions'
+         'haskell-async' 'haskell-transformers-base')
+makedepends=('ghc' 'haskell-hunit' 'haskell-hspec' 'haskell-hspec-contrib')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('75a6939ed0c395950738d569d2452b55acc373ead0361e97651218ec464816fffa1af5808b7af4d2ea7cd4339c028a4a1bee02f0bfd88fecb73a6888c083d651')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-lifted -f-build-examples
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}