[arch-commits] Commit in python2-ipykernel/repos (2 files)

Kyle Keen kkeen at archlinux.org
Fri May 10 22:53:16 UTC 2019


    Date: Friday, May 10, 2019 @ 22:53:15
  Author: kkeen
Revision: 465046

archrelease: copy trunk to community-any

Added:
  python2-ipykernel/repos/community-any/
  python2-ipykernel/repos/community-any/PKGBUILD
    (from rev 465045, python2-ipykernel/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: python2-ipykernel/repos/community-any/PKGBUILD (from rev 465045, python2-ipykernel/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2019-05-10 22:53:15 UTC (rev 465046)
@@ -0,0 +1,40 @@
+# Maintainer: Kyle Keen <keenerd at gmail.com>
+
+pkgname=python2-ipykernel
+pkgver=4.10.0
+pkgrel=1
+pkgdesc="The ipython kernel for Jupyter"
+arch=('any')
+url="https://pypi.org/project/ipykernel/"
+license=('BSD')
+depends=('python2-traitlets' 'python2-tornado' 'ipython2' 'python2-jupyter_client')
+makedepends=('python2-setuptools' 'ipython2' 'python2-jupyter_client')
+checkdepends=('python2-pytest' 'python2-mock' 'python2-nose')
+source=("ipykernel-$pkgver.tgz::https://github.com/ipython/ipykernel/archive/$pkgver.tar.gz")
+md5sums=('08e99a7b03b4dffd02af190d4c021524')
+
+# dep cycle with python-jupyter_client
+
+prepare() {
+  cd "$srcdir/ipykernel-$pkgver"
+
+  # https://github.com/ipython/ipykernel/issues/332
+  sed -i "s/executable='python'/executable='python2'/" setup.py
+}
+
+build() {
+  cd "$srcdir/ipykernel-$pkgver"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/ipykernel-$pkgver"
+  python2 -m pytest
+}
+
+package() {
+  cd "$srcdir/ipykernel-$pkgver"
+
+  python2 setup.py install  --root="$pkgdir" --optimize=1
+  install -Dm644 COPYING.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}


More information about the arch-commits mailing list