[arch-commits] Commit in haskell-lens/repos (2 files)

[Felix Yan]

    Date: Sunday, May 12, 2019 @ 12:16:06
  Author: felixonmars
Revision: 466333

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-lens/repos/community-staging-x86_64/
  haskell-lens/repos/community-staging-x86_64/PKGBUILD
    (from rev 466332, haskell-lens/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-lens/repos/community-staging-x86_64/PKGBUILD (from rev 466332, haskell-lens/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-12 12:16:06 UTC (rev 466333)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=lens
+pkgname=haskell-lens
+pkgver=4.17.1
+pkgrel=8
+pkgdesc="Lenses, Folds and Traversals"
+url="https://github.com/ekmett/lens/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-orphans' 'haskell-bifunctors' 'haskell-call-stack' 'haskell-comonad'
+         'haskell-contravariant' 'haskell-distributive' 'haskell-exceptions' 'haskell-free'
+         'haskell-hashable' 'haskell-kan-extensions' 'haskell-parallel' 'haskell-profunctors'
+         'haskell-reflection' 'haskell-semigroupoids' 'haskell-tagged' 'haskell-th-abstraction'
+         'haskell-transformers-compat' 'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('4fa7e00fd4f60440e7e10162ffb26cb3b557de6a3385160ed622cfa86a9c7bb0ab593a9db04ce04f581183e99d9d066d1e2398002eef36770044c900c294896b')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-j -ftrustworthy -f-safe -ftest-templates -ftest-properties -ftest-hunit \
+            -ftest-doctests -f-dump-splices -f-old-inline-pragmas -finlining \
+            -f-benchmark-uniplate
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}