[arch-commits] Commit in haskell-zip-archive/repos (2 files)

[Felix Yan]

    Date: Sunday, May 12, 2019 @ 15:13:15
  Author: felixonmars
Revision: 466606

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-zip-archive/repos/community-staging-x86_64/
  haskell-zip-archive/repos/community-staging-x86_64/PKGBUILD
    (from rev 466605, haskell-zip-archive/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-zip-archive/repos/community-staging-x86_64/PKGBUILD (from rev 466605, haskell-zip-archive/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-12 15:13:15 UTC (rev 466606)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=zip-archive
+pkgname=haskell-zip-archive
+pkgver=0.4.1
+pkgrel=5
+pkgdesc="Library for creating and modifying zip archives."
+url="https://github.com/jgm/zip-archive"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-digest' 'haskell-old-time' 'haskell-temporary'
+         'haskell-zlib')
+makedepends=('ghc' 'haskell-hunit' 'unzip')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/jgm/zip-archive/archive/$pkgver.tar.gz")
+sha512sums=('a921f54928690844e3976c38de6c98f2936c39a79b9ec8f23b6b57e17eedae5129201337fe363f6a8bb593c4dad94cb54da4379456c0a92c4ecdd24965388714')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-executable -fsplitbase
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}