[arch-commits] Commit in kpeople/repos (testing-x86_64 testing-x86_64/PKGBUILD)

Antonio Rojas arojas at archlinux.org
Mon May 13 20:09:10 UTC 2019


    Date: Monday, May 13, 2019 @ 20:09:09
  Author: arojas
Revision: 353222

archrelease: copy trunk to testing-x86_64

Added:
  kpeople/repos/testing-x86_64/
  kpeople/repos/testing-x86_64/PKGBUILD
    (from rev 353221, kpeople/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: kpeople/repos/testing-x86_64/PKGBUILD (from rev 353221, kpeople/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-05-13 20:09:09 UTC (rev 353222)
@@ -0,0 +1,37 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgname=kpeople
+pkgver=5.58.0
+pkgrel=1
+pkgdesc='A library that provides access to all contacts and the people who hold them'
+arch=(x86_64)
+url='https://community.kde.org/Frameworks'
+license=(LGPL)
+depends=(kservice kwidgetsaddons kitemviews)
+makedepends=(extra-cmake-modules doxygen qt5-tools qt5-declarative)
+optdepends=('qt5-declarative: QML bindings')
+groups=(kf5)
+source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('2588f7a4df4c03fe756d9e766120e35b0f991df5c8e5f75c3a507cc5739ded32'
+            'SKIP')
+validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() { 
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_QCH=ON
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}


More information about the arch-commits mailing list