[arch-commits] Commit in pandoc/repos (2 files)

[Felix Yan]

    Date: Thursday, May 16, 2019 @ 19:46:36
  Author: felixonmars
Revision: 467572

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc/repos/community-staging-x86_64/
  pandoc/repos/community-staging-x86_64/PKGBUILD
    (from rev 467571, pandoc/trunk/PKGBUILD)

----------+
 PKGBUILD |   65 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

Copied: pandoc/repos/community-staging-x86_64/PKGBUILD (from rev 467571, pandoc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-16 19:46:36 UTC (rev 467572)
@@ -0,0 +1,65 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc
+pkgver=2.7.2
+pkgrel=36
+pkgdesc='Conversion between markup formats'
+url='https://pandoc.org'
+license=('GPL')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-http' 'haskell-juicypixels' 'haskell-sha' 'haskell-aeson'
+         'haskell-aeson-pretty' 'haskell-attoparsec' 'haskell-base-compat' 'haskell-base64-bytestring'
+         'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-case-insensitive' 'haskell-cmark-gfm'
+         'haskell-data-default' 'haskell-doctemplates' 'haskell-exceptions' 'haskell-glob'
+         'haskell-haddock-library' 'haskell-ipynb' 'haskell-skylighting' 'haskell-hslua'
+         'haskell-hslua-module-text' 'haskell-http-client' 'haskell-syb' 'haskell-hsyaml' 'haskell-http-client-tls'
+         'haskell-http-types' 'haskell-safe' 'haskell-split' 'haskell-texmath'
+         'haskell-network' 'haskell-pandoc-types' 'haskell-random' 'haskell-scientific'
+         'haskell-tagsoup' 'haskell-temporary' 'haskell-network-uri' 'haskell-unicode-transforms'
+         'haskell-unordered-containers' 'haskell-zip-archive' 'haskell-vector' 'haskell-xml'
+         'haskell-zlib')
+optdepends=('pandoc-citeproc: for citation rendering with pandoc-citeproc filter'
+            'pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
+            'texlive-core: for pdf output')
+conflicts=('haskell-pandoc')
+replaces=('haskell-pandoc')
+makedepends=('ghc' 'haskell-diff' 'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck'
+             'haskell-tasty-golden' 'haskell-quickcheck' 'haskell-executable-path')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('f0d6a700413d1a70b6ca8f69883afda27248dcf5315a1819127163ad8e239fd19d2ec8462e3a793a67d3f86d02b364fa00ac5de735a77a63e737a1a2b92ef00b')
+
+prepare() {
+    cd "${srcdir}/$pkgname-${pkgver}"
+    sed -i 's/< *0.2/<1/' $pkgname.cabal
+
+    # TODO: find a better solution
+    sed -i "s|let env' = dynlibEnv ++ |let env' = dynlibEnv ++ [(\"LD_LIBRARY_PATH\", \"$PWD/dist/build\")] ++ |" test/Tests/Command.hs
+}
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgbase}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-trypandoc -f-embed_data_files -f-static
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup test || warning "Tests failed"
+}
+
+package() {
+    cd "${srcdir}/${pkgbase}-${pkgver}"
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/COPYING.md"
+}