[arch-commits] Commit in haskell-hakyll/repos (2 files)

[Felix Yan]

    Date: Friday, May 17, 2019 @ 14:59:41
  Author: felixonmars
Revision: 467707

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hakyll/repos/community-staging-x86_64/
  haskell-hakyll/repos/community-staging-x86_64/PKGBUILD
    (from rev 467706, haskell-hakyll/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-hakyll/repos/community-staging-x86_64/PKGBUILD (from rev 467706, haskell-hakyll/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-17 14:59:41 UTC (rev 467707)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hakyll
+pkgname=haskell-hakyll
+pkgver=4.12.5.2
+pkgrel=3
+pkgdesc="A static website compiler library"
+url="http://jaspervdj.be/hakyll"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-cryptohash'
+         'haskell-data-default' 'haskell-file-embed' 'haskell-fsnotify' 'haskell-http-conduit'
+         'haskell-http-types' 'haskell-lrucache' 'haskell-network-uri'
+         'haskell-optparse-applicative' 'pandoc' 'pandoc-citeproc' 'haskell-random'
+         'haskell-regex-tdfa' 'haskell-resourcet' 'haskell-scientific' 'haskell-tagsoup'
+         'haskell-time-locale-compat' 'haskell-unordered-containers' 'haskell-vector'
+         'haskell-wai' 'haskell-wai-app-static' 'haskell-warp' 'haskell-yaml')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('715324fa19b85e8f39e33b4d5082a04f40fc667737b41117da68a6a0eedad288a551929fa2eea636dd421d4d416996125ff9d83752c7daaf64ecc191e9790469')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fcheckexternal -fwatchserver -fpreviewserver -fusepandoc
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup test || warning "https://github.com/jaspervdj/hakyll/issues/682"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}