[arch-commits] Commit in digikam/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Saturday, May 18, 2019 @ 08:21:12
  Author: felixonmars
Revision: 353576

archrelease: copy trunk to staging-x86_64

Added:
  digikam/repos/staging-x86_64/
  digikam/repos/staging-x86_64/PKGBUILD
    (from rev 353575, digikam/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: digikam/repos/staging-x86_64/PKGBUILD (from rev 353575, digikam/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-05-18 08:21:12 UTC (rev 353576)
@@ -0,0 +1,49 @@
+# $Id: PKGBUILD 320127 2018-03-24 09:48:28Z arojas $
+# Maintainer: Ronald van Haren <ronald at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+
+pkgname=digikam
+_pkgver=6.1.0
+pkgver=${_pkgver//-/_} # for beta versions
+pkgrel=2
+pkgdesc="An advanced digital photo management application"
+arch=(x86_64)
+license=(GPL)
+url="https://www.digikam.org/"
+depends=(lensfun opencv akonadi-contacts knotifyconfig libksane kfilemetadata qtav marble-common threadweaver kcalcore
+         qt5-xmlpatterns libmagick)
+makedepends=(extra-cmake-modules doxygen eigen boost kdoctools libkvkontakte)
+optdepends=('hugin: panorama tool' 'qt5-imageformats: support for additional image formats (WEBP, TIFF)'
+            'libkvkontakte: VKontakte plugin')
+source=("https://download.kde.org/stable/$pkgname/$_pkgver/$pkgname-$_pkgver.tar.xz"{,.sig})
+sha256sums=('c487be4047d73f179cddff26355b6f3b270f407f73009d14b37f2c12039fffe7'
+            'SKIP')
+validpgpkeys=(D1CF2444A7858C5F2FB095B74A77747BC2386E50) # digiKam.org (digiKam project) <digikamdeveloper at gmail.com>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+
+  cmake ../$pkgname-$_pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF \
+    -DENABLE_KFILEMETADATASUPPORT=ON \
+    -DENABLE_MEDIAPLAYER=ON \
+    -DENABLE_AKONADICONTACTSUPPORT=ON \
+    -DENABLE_MYSQLSUPPORT=ON \
+    -DENABLE_APPSTYLES=ON \
+    -DENABLE_QWEBENGINE=ON \
+    -DOpenGL_GL_PREFERENCE=GLVND
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}