[arch-commits] Commit in gwenview/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Antonio Rojas
arojas at archlinux.org
Wed May 22 15:20:06 UTC 2019
Date: Wednesday, May 22, 2019 @ 15:20:05
Author: arojas
Revision: 353839
archrelease: copy trunk to staging-x86_64
Added:
gwenview/repos/staging-x86_64/
gwenview/repos/staging-x86_64/PKGBUILD
(from rev 353838, gwenview/trunk/PKGBUILD)
----------+
PKGBUILD | 47 +++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 47 insertions(+)
Copied: gwenview/repos/staging-x86_64/PKGBUILD (from rev 353838, gwenview/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2019-05-22 15:20:05 UTC (rev 353839)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=gwenview
+pkgver=19.04.1
+pkgrel=3
+pkgdesc="A fast and easy to use image viewer"
+url='https://kde.org/applications/graphics/gwenview/'
+arch=(x86_64)
+license=(GPL LGPL FDL)
+groups=(kde-applications kdegraphics)
+depends=(kactivities baloo libkipi libkdcraw kparts kitemmodels cfitsio phonon-qt5)
+optdepends=('qt5-imageformats: support for tiff, webp, and more image formats'
+ 'kimageformats: support for dds, xcf, exr, psd, and more image formats'
+ 'kipi-plugins: export to various online services'
+ 'kamera: import pictures from gphoto2 cameras')
+makedepends=(extra-cmake-modules kdoctools)
+source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
+ gwenview-exiv2-0.27.1.patch::"https://cgit.kde.org/gwenview.git/patch/?id=172560b8")
+sha256sums=('636498100284be86194d328c40ed70166cc96a5fc7665090e4a1ca9538b2f13c'
+ 'SKIP'
+ 'a564cc34544769bf4c25e9c7e5a70248b1c1af33e4d06df65badb70ab72acadf')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid at kde.org>
+ F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+ mkdir -p build
+
+ cd $pkgname-$pkgver
+ patch -p1 -i ../gwenview-exiv2-0.27.1.patch # Fix build with exiv2 0.27.1
+}
+
+build() {
+ cd build
+ cmake ../$pkgname-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DGWENVIEW_SEMANTICINFO_BACKEND="Baloo" \
+ -DBUILD_TESTING=OFF
+ make
+}
+
+package() {
+ cd build
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list