[arch-commits] Commit in haskell-yesod-form/repos (2 files)

[Felix Yan]

    Date: Wednesday, May 22, 2019 @ 22:46:02
  Author: felixonmars
Revision: 468856

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod-form/repos/community-staging-x86_64/
  haskell-yesod-form/repos/community-staging-x86_64/PKGBUILD
    (from rev 468855, haskell-yesod-form/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-yesod-form/repos/community-staging-x86_64/PKGBUILD (from rev 468855, haskell-yesod-form/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-22 22:46:02 UTC (rev 468856)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yesod-form
+pkgname=haskell-yesod-form
+pkgver=1.6.4
+pkgrel=62
+pkgdesc="Form handling support for Yesod Web Framework"
+url="http://www.yesodweb.com/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-blaze-builder' 'haskell-blaze-html'
+         'haskell-blaze-markup' 'haskell-byteable' 'haskell-data-default' 'haskell-email-validate'
+         'haskell-network-uri' 'haskell-persistent' 'haskell-resourcet' 'haskell-shakespeare'
+         'haskell-wai' 'haskell-xss-sanitize' 'haskell-yesod-core' 'haskell-yesod-persistent')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('26900428efe018b5e7bbe4c26ca83bc3b2425c7e9fa777c107898a4274c663572011330cd233c18ceeb7e0dea1965640541142736469580de0f309aa7f765f63')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fnetwork-uri
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh   "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}