[arch-commits] Commit in (3 files)

Maxime Gauduin alucryd at archlinux.org
Thu May 23 14:40:32 UTC 2019


    Date: Thursday, May 23, 2019 @ 14:40:31
  Author: alucryd
Revision: 469408

add python-quart

Added:
  python-quart/
  python-quart/trunk/
  python-quart/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python-quart/trunk/PKGBUILD
===================================================================
--- python-quart/trunk/PKGBUILD	                        (rev 0)
+++ python-quart/trunk/PKGBUILD	2019-05-23 14:40:31 UTC (rev 469408)
@@ -0,0 +1,50 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=python-quart
+pkgver=0.9.1
+pkgrel=1
+pkgdesc='A Python ASGI web microframework with the same API as Flask'
+url=https://gitlab.com/pgjones/quart
+arch=(any)
+license=(MIT)
+depends=(
+  hypercorn
+  python-aiofiles
+  python-blinker
+  python-click
+  python-itsdangerous
+  python-jinja
+  python-multidict
+  python-sortedcontainers
+)
+makedepends=(
+  git
+  python-asynctest
+  python-hypothesis
+  python-pytest
+  python-pytest-asyncio
+  python-setuptools
+)
+source=(git+https://gitlab.com/pgjones/quart.git#tag=${pkgver})
+sha256sums=(SKIP)
+
+build() {
+  cd quart
+
+  python setup.py build
+}
+
+check() {
+  cd quart
+
+  python setup.py test
+}
+
+package() {
+  cd quart
+
+  python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
+  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/python-quart/
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list