[arch-commits] Commit in liteide/repos (2 files)

[Alexander Rødseth]

    Date: Friday, May 24, 2019 @ 11:38:16
  Author: arodseth
Revision: 469597

archrelease: copy trunk to community-staging-x86_64

Added:
  liteide/repos/community-staging-x86_64/
  liteide/repos/community-staging-x86_64/PKGBUILD
    (from rev 469596, liteide/trunk/PKGBUILD)

----------+
 PKGBUILD |   93 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 93 insertions(+)

Copied: liteide/repos/community-staging-x86_64/PKGBUILD (from rev 469596, liteide/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-24 11:38:16 UTC (rev 469597)
@@ -0,0 +1,93 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: spambanane <happy.house at gmx.de>
+# Contributor: Matteo <matteo.dek at gmail.com>
+# Contributor: Matthew Zimmerman <mzimmerman at gmail.com>
+
+pkgname=liteide
+pkgver=36
+pkgrel=2
+pkgdesc='IDE for editing and building projects written in the Go programming language'
+license=(LGPL)
+arch=(x86_64)
+url='https://github.com/visualfc/liteide'
+makedepends=(go git imagemagick mercurial setconf)
+depends=(go-tools qt5-webkit)
+optdepends=('go: go compiler'
+            'gcc-go: go compiler')
+options=(!strip !emptydirs)
+source=("$pkgname-x$pkgver::git+https://github.com/visualfc/liteide.git#tag=x$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  chmod +x "liteide-x"$pkgver"/build/"*_*.sh
+
+  # Fix for FS#4662 until fixed by upstream
+  cd "liteide-x$pkgver/liteidex/os_deploy/linux/liteenv"
+  sed -i 's|^GOROOT|#GOROOT|g' linux32.env
+  sed -i 's|^GOROOT|#GOROOT|g' linux64.env
+
+  # Fix the libpng warning: iCCP: known incorrect sRGB profile
+  find "$srcdir" -type f -iname "*.png" -exec mogrify -strip '{}' \;
+}
+
+build() {
+  cd "liteide-x$pkgver/build"
+
+  mkdir -p go
+  export GOPATH="$PWD/go"
+  export QTDIR=/usr
+
+  ./update_pkg.sh
+  ./build_linux.sh
+}
+
+package() {
+  cd "liteide-x$pkgver/build/liteide"
+
+  # Directories
+  install -d \
+    "$pkgdir/usr/lib/liteide" \
+    "$pkgdir/usr/share/liteide" \
+    "$pkgdir/usr/share/doc/$pkgname"
+
+  # Executables
+  ls bin
+  for binary in gotools gocode liteide; do # goimports
+    install -Dm755 "bin/$binary" "$pkgdir/usr/bin/$binary"
+  done
+  ln -s /usr/bin/liteide "$pkgdir/usr/bin/golangide"
+
+  cd "$srcdir/liteide-x$pkgver/liteidex"
+
+  # Resources
+  cp -r deploy/* os_deploy/* "$pkgdir/usr/share/liteide"
+
+  # Libraries and plugins
+  cp -r liteide/lib/liteide/* "$pkgdir/usr/lib/liteide"
+  chmod -x "$pkgdir/usr/lib/liteide/plugins/"*
+
+  # License and license exception
+  install -Dm644 LICENSE.LGPL \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm644 LGPL_EXCEPTION.TXT \
+    "$pkgdir/usr/share/licenses/$pkgname/LGPL_EXCEPTION"
+
+  cd "$srcdir"
+
+  # Desktop shortcut
+  install -Dm644 "liteide-x$pkgver/liteidex/$pkgname.desktop" \
+    "$pkgdir/usr/share/applications/$pkgname.desktop"
+  install -d "$pkgdir/usr/share/pixmaps"
+  ln -s /usr/share/liteide/welcome/images/liteide400.png \
+    "$pkgdir/usr/share/pixmaps/$pkgname.png"
+
+  # Cleaning up
+  rm -rf "$pkgdir/usr/share/$pkgname/doc"
+
+  # Fix for FS#38781
+  mv "$pkgdir/usr/share/liteide/linux/liteenv" \
+    "$pkgdir/usr/share/liteide/liteenv"
+}
+
+# getver: raw.githubusercontent.com/visualfc/liteide/master/build/liteide_archlinux/PKGBUILD
+# vim: ts=2 sw=2 et: