[arch-commits] Commit in (pylama pylama/repos pylama/trunk pylama/trunk/PKGBUILD)

[Felix Yan]

    Date: Friday, May 24, 2019 @ 17:34:36
  Author: felixonmars
Revision: 469654

addpkg: pylama 7.7.1-1

Added:
  pylama/
  pylama/repos/
  pylama/trunk/
  pylama/trunk/PKGBUILD

----------+
 PKGBUILD |   33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

Added: pylama/trunk/PKGBUILD
===================================================================
--- pylama/trunk/PKGBUILD	                        (rev 0)
+++ pylama/trunk/PKGBUILD	2019-05-24 17:34:36 UTC (rev 469654)
@@ -0,0 +1,33 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Pieter Goetschalckx <3.14.e.ter at gmail dot com>
+# Contributor: Stijn Seghers (Procrat) <stijnseghers at gmail dot com>
+
+pkgname=pylama
+pkgver=7.7.1
+pkgrel=1
+pkgdesc="Code audit tool for python"
+arch=('any')
+url="https://github.com/klen/pylama"
+license=('GPL3')
+depends=('python-pycodestyle' 'python-pydocstyle' 'python-pyflakes' 'python-mccabe')
+checkdepends=('python-pytest' 'git' 'mypy')
+optdepends=('python-radon: radon support')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/klen/pylama/archive/$pkgver.tar.gz")
+sha256sums=('acec2b80ad6a4781dc2626992b10ecac7b81be6c0145750c11688c281298f6fe')
+
+build() {
+  cd $pkgname-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd $pkgname-$pkgver
+  python setup.py install --root="$PWD/tmp_install" --optimize=1
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python3.7/site-packages:$PYTHONPATH:$PWD/tests" py.test --pylama pylama
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python3.7/site-packages:$PYTHONPATH:$PWD/tests" py.test tests -k 'not test_eradicate'
+}
+
+package() {
+  cd $pkgname-$pkgver
+  python setup.py install --root="$pkgdir/" --optimize=1
+}