[arch-commits] Commit in python-yaml/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat May 25 05:27:28 UTC 2019


    Date: Saturday, May 25, 2019 @ 05:27:27
  Author: felixonmars
Revision: 469721

archrelease: copy trunk to community-testing-x86_64

Added:
  python-yaml/repos/community-testing-x86_64/
  python-yaml/repos/community-testing-x86_64/PKGBUILD
    (from rev 469720, python-yaml/trunk/PKGBUILD)

----------+
 PKGBUILD |   64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

Copied: python-yaml/repos/community-testing-x86_64/PKGBUILD (from rev 469720, python-yaml/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-05-25 05:27:27 UTC (rev 469721)
@@ -0,0 +1,64 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Michal Bozon <michal.bozon__at__gmail.com>
+
+pkgbase=python-yaml
+pkgname=(python-yaml python2-yaml)
+pkgver=5.1
+pkgrel=1
+pkgdesc='Python bindings for YAML, using fast libYAML library'
+url='http://pyyaml.org/wiki/PyYAML'
+arch=('x86_64')
+license=('MIT')
+makedepends=('python' 'python2' 'libyaml' 'cython' 'cython2')
+source=(http://pyyaml.org/download/pyyaml/PyYAML-${pkgver}.tar.gz)
+sha512sums=('8f27f92bdfa310a99dd6d83947332cc033fa18f0011998bb585ad5c4340a2da20d8c20bfdb53beaae15651198d1240c986818379b0a05b230f74d1f30f53e7fd')
+
+prepare() {
+  # Force cython rebuild
+  rm PyYAML-$pkgver/ext/_yaml.c
+
+  cp -a PyYAML-$pkgver{,-py2}
+}
+
+build() {
+  msg2 "Building python..."
+  (cd PyYAML-$pkgver
+    python setup.py --with-libyaml build
+  )
+  msg2 "Building python2..."
+  (cd PyYAML-$pkgver-py2
+    python2 setup.py --with-libyaml build
+  )
+}
+
+check() {
+  msg2 "Checking python..."
+  (cd PyYAML-$pkgver
+    python setup.py test || warning "https://github.com/yaml/pyyaml/issues/184"
+  )
+  msg2 "Checking python2..."
+  (cd PyYAML-$pkgver-py2
+    python2 setup.py test || warning "https://github.com/yaml/pyyaml/issues/184"
+  )
+}
+
+package_python-yaml() {
+  depends=('python' 'libyaml')
+
+  cd PyYAML-$pkgver
+  python setup.py  --with-libyaml install --prefix=/usr --root="${pkgdir}" -O1 --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+  install -Dm 644 CHANGES README -t "${pkgdir}"/usr/share/doc/${pkgname}
+}
+
+package_python2-yaml() {
+  depends=('python2' 'libyaml')
+
+  cd PyYAML-$pkgver-py2
+  python2 setup.py --with-libyaml install --prefix=/usr --root="${pkgdir}" -O1 --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+  install -Dm 644 CHANGES README -t "${pkgdir}"/usr/share/doc/${pkgname}
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list