[arch-commits] Commit in gnumeric/repos (3 files)

[Evangelos Foutras]

    Date: Saturday, May 25, 2019 @ 11:54:04
  Author: foutrelis
Revision: 354257

archrelease: copy trunk to staging-x86_64

Added:
  gnumeric/repos/staging-x86_64/
  gnumeric/repos/staging-x86_64/PKGBUILD
    (from rev 354256, gnumeric/trunk/PKGBUILD)
  gnumeric/repos/staging-x86_64/revert-warnings.patch
    (from rev 354256, gnumeric/trunk/revert-warnings.patch)

-----------------------+
 PKGBUILD              |   50 ++++++++++++++++++++++++++++++++++++++++++++++++
 revert-warnings.patch |   11 ++++++++++
 2 files changed, 61 insertions(+)

Copied: gnumeric/repos/staging-x86_64/PKGBUILD (from rev 354256, gnumeric/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-05-25 11:54:04 UTC (rev 354257)
@@ -0,0 +1,50 @@
+# Maintainer: Eric Belanger <eric at archlinux.org>
+# Contributor: Kritoke <typeolinux at yahoo.com>
+
+pkgname=gnumeric
+pkgver=1.12.44
+pkgrel=2
+pkgdesc="A GNOME Spreadsheet Program"
+arch=('x86_64')
+url="https://www.gnome.org/projects/gnumeric/"
+license=('GPL')
+depends=('goffice')
+makedepends=('intltool' 'psiconv' 'pygobject-devel' docbook-xml
+             'gobject-introspection' 'python2-gobject' gtk-doc autoconf-archive git yelp-tools)
+optdepends=('python2-gobject: for python2 plugin support'
+            'perl: for perl plugin support'
+            'psiconv: for Psion 5 file support'
+            'yelp: for viewing the help manual')
+_commit=3208168044d1b510255509813730f76a1d5df077  # tags/GNUMERIC_1_12_44^0
+source=("git+https://gitlab.gnome.org/GNOME/gnumeric.git#commit=$_commit"
+        revert-warnings.patch)
+sha256sums=('SKIP'
+            'bcafca016b809000c2a5bf911e2e3dfa4de28f9e541d9964574cac5c7ce09e53')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^GNUMERIC_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  git cherry-pick -n fdb43346579e9db9122609b1b390d59a94ecd782  
+  sed 's/@GIOVERRIDESDIR@/$(DESTDIR)@GIOVERRIDESDIR@/g' -i introspection/Makefile.am
+  sed 's/python -c/$PYTHON -c/' -i configure.ac
+  patch -Np0 -i ../revert-warnings.patch
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --disable-schemas-compile --enable-introspection --disable-silent-rules
+
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="${pkgdir}" install
+}

Copied: gnumeric/repos/staging-x86_64/revert-warnings.patch (from rev 354256, gnumeric/trunk/revert-warnings.patch)
===================================================================
--- staging-x86_64/revert-warnings.patch	                        (rev 0)
+++ staging-x86_64/revert-warnings.patch	2019-05-25 11:54:04 UTC (rev 354257)
@@ -0,0 +1,11 @@
+--- configure.ac.orig	2013-03-13 16:09:02.355422066 +0000
++++ configure.ac	2013-03-13 16:09:26.701917153 +0000
+@@ -269,8 +269,6 @@
+ 			 -Wchar-subscripts -Wwrite-strings \
+ 			 -Wdeclaration-after-statement -Wnested-externs \
+ 			 -Wmissing-noreturn \
+-			 -Werror=missing-prototypes -Werror=nested-externs \
+-			 -Werror=implicit-function-declaration \
+ 			 -Wmissing-declarations -Wno-pointer-sign \
+ 			 -Werror=format-security -Wbitwise -Wcast-to-as \
+ 			 -Wdefault-bitfield-sign -Wdo-while -Wparen-string \