[arch-commits] Commit in (4 files)

[Eli Schwartz]

    Date: Tuesday, May 28, 2019 @ 19:48:12
  Author: eschwartz
Revision: 473031

addpkg: python-dephell-links 0.1.4-1

part of "dephell" tool

Added:
  python-dephell-links/
  python-dephell-links/repos/
  python-dephell-links/trunk/
  python-dephell-links/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: python-dephell-links/trunk/PKGBUILD
===================================================================
--- python-dephell-links/trunk/PKGBUILD	                        (rev 0)
+++ python-dephell-links/trunk/PKGBUILD	2019-05-28 19:48:12 UTC (rev 473031)
@@ -0,0 +1,42 @@
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+
+_pkgname=dephell_links
+pkgname=python-dephell-links
+pkgver=0.1.4
+pkgrel=1
+pkgdesc="Parse dependency links"
+arch=('any')
+url="https://github.com/dephell/${_pkgname}"
+license=('MIT')
+depends=('python-attrs')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest')
+source=("https://files.pythonhosted.org/packages/source/${_pkgname:0:1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
+sha256sums=('421db613fb291bc723aafe3e331e1691d15b8753bb0ded63e8e991e8422ceaf6')
+b2sums=('e5af5d8f139fbd05b092aa73953453ee9af57df73998ab8a05e0b89cfc7476197db634f99d79a868dcee7c962698ec9c6e5ed3cf12b5fa9fbc99be93a155a114')
+
+prepare() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    # pycache slipped into release tarballs
+    find . -name \*.pyc -delete
+}
+
+build(){
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python setup.py build
+}
+
+check() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python -m pytest
+}
+
+package() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}