[arch-commits] Commit in (4 files)
Eli Schwartz
eschwartz at archlinux.org
Tue May 28 20:19:14 UTC 2019
Date: Tuesday, May 28, 2019 @ 20:19:13
Author: eschwartz
Revision: 473054
addpkg: python-dephell-shells 0.1.3-1
part of "dephell" tool
Added:
python-dephell-shells/
python-dephell-shells/repos/
python-dephell-shells/trunk/
python-dephell-shells/trunk/PKGBUILD
----------+
PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
1 file changed, 42 insertions(+)
Added: python-dephell-shells/trunk/PKGBUILD
===================================================================
--- python-dephell-shells/trunk/PKGBUILD (rev 0)
+++ python-dephell-shells/trunk/PKGBUILD 2019-05-28 20:19:13 UTC (rev 473054)
@@ -0,0 +1,42 @@
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+
+_pkgname=dephell_shells
+pkgname=python-dephell-shells
+pkgver=0.1.3
+pkgrel=1
+pkgdesc="Activate virtual environment for current shell"
+arch=('any')
+url="https://github.com/dephell/${_pkgname}"
+license=('MIT')
+depends=('python-attrs' 'python-pexpect' 'python-shellingham')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest')
+source=("https://files.pythonhosted.org/packages/source/${_pkgname:0:1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
+sha256sums=('420de1c53cfd6c4a6b11aef5d8a93701b479ab6ef72bae8e0b5b51167e7ba1f9')
+b2sums=('29c29131e428af3b9680056f1ace55eedc6e4efa8ad115e78a4879fdb6665abc40752e1d4d1ab46a932ba4cae9d17f3ee887ccd8a617663415386ca7b4e2a335')
+
+prepare() {
+ cd "${srcdir}"/${_pkgname}-${pkgver}
+
+ # pycache slipped into release tarballs
+ find . -name \*.pyc -delete
+}
+
+build(){
+ cd "${srcdir}"/${_pkgname}-${pkgver}
+
+ python setup.py build
+}
+
+check() {
+ cd "${srcdir}"/${_pkgname}-${pkgver}
+
+ python -m pytest
+}
+
+package() {
+ cd "${srcdir}"/${_pkgname}-${pkgver}
+
+ python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+ install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}
More information about the arch-commits
mailing list