[arch-commits] Commit in (4 files)

[Eli Schwartz]

    Date: Tuesday, May 28, 2019 @ 20:28:22
  Author: eschwartz
Revision: 473061

addpkg: python-dephell-markers 0.2.6-1

part of "dephell" tool

Added:
  python-dephell-markers/
  python-dephell-markers/repos/
  python-dephell-markers/trunk/
  python-dephell-markers/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: python-dephell-markers/trunk/PKGBUILD
===================================================================
--- python-dephell-markers/trunk/PKGBUILD	                        (rev 0)
+++ python-dephell-markers/trunk/PKGBUILD	2019-05-28 20:28:22 UTC (rev 473061)
@@ -0,0 +1,42 @@
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+
+_pkgname=dephell_markers
+pkgname=python-dephell-markers
+pkgver=0.2.6
+pkgrel=1
+pkgdesc="Work with environment markers (PEP-496)"
+arch=('any')
+url="https://github.com/dephell/${_pkgname}"
+license=('MIT')
+depends=('python-attrs' 'python-dephell-specifier' 'python-packaging')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest')
+source=("https://files.pythonhosted.org/packages/source/${_pkgname:0:1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
+sha256sums=('fe4cb15a060973a58186b8bb0325b8d0a62cb14a31dbc3ee4a687dc619eb0685')
+b2sums=('3e55af5fdfd3a1050f8c97160223acc9a19e8ba8c256743eb3310d18dd258282f3db5100df3177514e27f8fbcf79d487f0467a202b775248f9f09218b58539e0')
+
+prepare() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    # pycache slipped into release tarballs
+    find . -name \*.pyc -delete
+}
+
+build(){
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python setup.py build
+}
+
+check() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python -m pytest
+}
+
+package() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}