[arch-commits] Commit in (4 files)

Eli Schwartz eschwartz at archlinux.org
Tue May 28 20:37:26 UTC 2019


    Date: Tuesday, May 28, 2019 @ 20:37:26
  Author: eschwartz
Revision: 473067

addpkg: python-dephell-discover 0.2.4-1

part of "dephell" tool

Added:
  python-dephell-discover/
  python-dephell-discover/repos/
  python-dephell-discover/trunk/
  python-dephell-discover/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: python-dephell-discover/trunk/PKGBUILD
===================================================================
--- python-dephell-discover/trunk/PKGBUILD	                        (rev 0)
+++ python-dephell-discover/trunk/PKGBUILD	2019-05-28 20:37:26 UTC (rev 473067)
@@ -0,0 +1,45 @@
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+
+_pkgname=dephell_discover
+pkgname=python-dephell-discover
+pkgver=0.2.4
+pkgrel=1
+pkgdesc="Find project modules and data files (packages and package_data for setup.py)"
+arch=('any')
+url="https://github.com/dephell/${_pkgname}"
+license=('MIT')
+depends=('python-attrs')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest')
+source=("https://files.pythonhosted.org/packages/source/${_pkgname:0:1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
+sha256sums=('be80a188e5624678812f966c8cd2e6b2db6b54239fd0fdeef1abbc1babfa1d85')
+b2sums=('65af6e838de96060eadf76851216fe26e94f88723fed2ea459f676bba0fa7876e2ff3c238110efbd55a744cbdd590ec3e3cdf6737fbe6069279da25efce1832c')
+
+prepare() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    # fix attr dependency, see https://github.com/dephell/dephell_discover/pull/3
+    sed -i '/install_requires/{s/attr/attrs/}' setup.py
+
+    # pycache slipped into release tarballs
+    find . -name \*.pyc -delete
+}
+
+build(){
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python setup.py build
+}
+
+check() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python -m pytest
+}
+
+package() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}


More information about the arch-commits mailing list