[arch-commits] Commit in haskell-temporary/repos (2 files)

[Felix Yan]

    Date: Thursday, May 30, 2019 @ 14:46:43
  Author: felixonmars
Revision: 474645

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-temporary/repos/community-staging-x86_64/
  haskell-temporary/repos/community-staging-x86_64/PKGBUILD
    (from rev 474644, haskell-temporary/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-temporary/repos/community-staging-x86_64/PKGBUILD (from rev 474644, haskell-temporary/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-05-30 14:46:43 UTC (rev 474645)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=temporary
+pkgname=haskell-temporary
+pkgver=1.3
+pkgrel=32
+pkgdesc="Portable temporary file and directory support"
+url="http://www.github.com/batterseapower/temporary"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-exceptions' 'haskell-random')
+makedepends=('ghc' 'haskell-base-compat' 'haskell-tasty' 'haskell-tasty-hunit')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('e3078caf54da95c4efa9e9c936b35a98b62296ecce2242cd4e103605a9d29e8a9d6c7027dbf50d02b6a893bea558ea5b07dbb1df7c59bf26d86db76ccf112f25')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}