[arch-commits] Commit in python-aws-sam-translator/repos (2 files)

Chih-Hsuan Yen yan12125 at archlinux.org
Fri May 31 14:18:35 UTC 2019


    Date: Friday, May 31, 2019 @ 14:18:34
  Author: yan12125
Revision: 475936

archrelease: copy trunk to community-testing-any

Added:
  python-aws-sam-translator/repos/community-testing-any/
  python-aws-sam-translator/repos/community-testing-any/PKGBUILD
    (from rev 475935, python-aws-sam-translator/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: python-aws-sam-translator/repos/community-testing-any/PKGBUILD (from rev 475935, python-aws-sam-translator/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2019-05-31 14:18:34 UTC (rev 475936)
@@ -0,0 +1,40 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+
+pkgname=python-aws-sam-translator
+pkgver=1.11.0
+pkgrel=2
+pkgdesc='AWS Serverless Application Model (AWS SAM) prescribes rules for expressing Serverless applications on AWS'
+arch=(any)
+url='https://github.com/awslabs/serverless-application-model'
+license=(Apache)
+depends=(python python-boto3 python-jsonschema python-six)
+makedepends=(python-setuptools)
+checkdepends=(python-pytest python-yaml python-mock python-parameterized)
+source=("$pkgname-$pkgver.tar.gz"::"https://github.com/awslabs/serverless-application-model/archive/v$pkgver.tar.gz")
+sha256sums=('2bf620d1d22ee28781eefe0cb47e121c3f40eab4b04635889936b0ec1847e4f2')
+
+prepare() {
+  cd serverless-application-model-$pkgver
+
+  # remove coverage.py options - running coverage as a non-developer does not make much sense
+  sed -i 's#addopts = .*##' pytest.ini
+
+  # backport of https://github.com/awslabs/serverless-application-model/pull/927
+  sed -i 's#jsonschema~=2.6#jsonschema~=3.0#' requirements/base.txt
+}
+
+build() {
+  cd serverless-application-model-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd serverless-application-model-$pkgver
+
+  pytest -v tests
+}
+
+package() {
+  cd serverless-application-model-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}



More information about the arch-commits mailing list