[arch-commits] Commit in gnome-music/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Monday, November 4, 2019 @ 04:16:36
  Author: felixonmars
Revision: 366662

archrelease: copy trunk to staging-x86_64

Added:
  gnome-music/repos/staging-x86_64/
  gnome-music/repos/staging-x86_64/PKGBUILD
    (from rev 366661, gnome-music/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: gnome-music/repos/staging-x86_64/PKGBUILD (from rev 366661, gnome-music/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-11-04 04:16:36 UTC (rev 366662)
@@ -0,0 +1,57 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-music
+pkgver=3.34.1
+pkgrel=2
+epoch=1
+pkgdesc="Music player and management application"
+url="https://wiki.gnome.org/Apps/Music"
+arch=(x86_64)
+license=(GPL)
+depends=(grilo grilo-plugins tracker-miners libdmapsharing libmediaart gtk3 gvfs
+         python-gobject python-cairo gst-plugins-base python-requests libdazzle)
+makedepends=(gobject-introspection git meson yelp-tools appstream-glib)
+optdepends=('gst-plugins-good: Extra media codecs'
+            'gst-plugins-ugly: Extra media codecs'
+            'gst-plugins-bad: Extra media codecs'
+            'gst-libav: Extra media codecs')
+groups=(gnome)
+_commit=3510127d0f0203d1cff7758a41dbd82bea2a2de6  # tags/3.34.1^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-music.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git"
+        "git+https://gitlab.gnome.org/mschraal/gfm.git")
+sha256sums=('SKIP'
+            'SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.subprojects/libgd.url "$srcdir/libgd"
+  git config --local submodule.subprojects/gfm.url "$srcdir/gfm"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build
+  ninja -C build
+}
+
+check() {
+  # appdata style violations
+  meson test -C build --print-errorlogs || :
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+
+  python -m compileall -d /usr/lib "$pkgdir/usr/lib"
+  python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
+}