[arch-commits] Commit in urh/repos (2 files)

[Felix Yan]

    Date: Monday, November 4, 2019 @ 05:47:45
  Author: felixonmars
Revision: 523240

archrelease: copy trunk to community-staging-x86_64

Added:
  urh/repos/community-staging-x86_64/
  urh/repos/community-staging-x86_64/PKGBUILD
    (from rev 523239, urh/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: urh/repos/community-staging-x86_64/PKGBUILD (from rev 523239, urh/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-11-04 05:47:45 UTC (rev 523240)
@@ -0,0 +1,56 @@
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinuc.org>
+# Contributor: Johannes Pohl <johannes.pohl90 at gmail.com>
+
+pkgname=urh
+pkgver=2.8.0
+pkgrel=2
+pkgdesc='Universal Radio Hacker: investigate wireless protocols like a boss'
+arch=('x86_64')
+url='https://github.com/jopohl/urh'
+license=('GPL3')
+depends=('python' 'python-pyqt5' 'python-numpy' 'python-psutil' 'python-pyzmq' 'cython')
+makedepends=('gcc' 'python-setuptools'
+             'airspy' 'hackrf' 'libuhd' 'limesuite' 'rtl-sdr') # Optional
+checkdepends=('python-pytest-runner' 'python-pytest-xdist' 'xorg-server-xvfb')
+optdepends=('airspy: Airspy backend'
+            'cython: compiling native modules inside URH'
+            'hackrf: HackRF backend'
+            'libuhd: USRP backend'
+            'limesuite: LimeSDR backend'
+            'rtl-sdr: RTL-SDR backend'
+            'gnuradio: GNURadio backend'
+            'gnuradio-osmosdr: OsmoSDR backend, via GNURadio'
+            'python-pyaudio: Soundcard backend')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/jopohl/urh/archive/v$pkgver.tar.gz")
+sha512sums=('0d72c5b008071d0855cb36f3f995b60e38e557cbb19b4a42f0ed7db920dc78065bc6b60b160ab277c533f725417b58f1fb377f72a5d9ca183fa4537f8da14992')
+
+prepare() {
+  cd $pkgname-$pkgver
+
+  # Issues with PyQt, see https://github.com/jopohl/urh/issues/623
+  rm tests/{test_filter.py,test_plugins.py}
+}
+
+build() {
+  cd $pkgname-$pkgver
+
+  python setup.py build build_ext
+  python src/urh/cythonext/build.py
+}
+
+check() {
+  cd $pkgname-$pkgver
+
+  xvfb-run pytest --boxed
+}
+
+package() {
+  cd $pkgname-$pkgver
+
+  python setup.py install --root="$pkgdir" -O1 --skip-build
+
+  install -Dm644 ./data/urh.desktop "$pkgdir"/usr/share/applications/urh.desktop
+  install -Dm 644 data/icons/appicon.png "$pkgdir"/usr/share/pixmaps/urh.png
+  install -Dm 644 README.md "$pkgdir"/usr/share/doc/$pkgname/README
+}
+