[arch-commits] Commit in python-plyvel/repos (2 files)

[Felix Yan]

    Date: Monday, November 4, 2019 @ 06:27:33
  Author: felixonmars
Revision: 523400

archrelease: copy trunk to community-staging-x86_64

Added:
  python-plyvel/repos/community-staging-x86_64/
  python-plyvel/repos/community-staging-x86_64/PKGBUILD
    (from rev 523399, python-plyvel/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: python-plyvel/repos/community-staging-x86_64/PKGBUILD (from rev 523399, python-plyvel/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-11-04 06:27:33 UTC (rev 523400)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+
+pkgname=(python-plyvel python2-plyvel)
+pkgver=1.1.0
+pkgrel=2
+pkgdesc="A fast and feature-rich Python interface to LevelDB"
+arch=('x86_64')
+license=('BSD')
+url="https://github.com/wbolster/plyvel"
+makedepends=('cython' 'cython2' 'python-setuptools' 'python2-setuptools' 'leveldb')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("https://pypi.io/packages/source/p/plyvel/plyvel-$pkgver.tar.gz")
+sha512sums=('4d9b20f7e047d75af14d530519b4360194a18aa423a57ac4596441e47528bbc9f8e3ff763dd91da4c115cb1e4a6f34f01bbd47f4be49be110b2f6e3c7b8bdb3a')
+
+prepare() {
+  # Shipped egg-info has wrong permission etc
+  (cd plyvel-$pkgver; make clean)
+
+  cp -a plyvel-$pkgver{,-py2}
+
+  sed -i 's/cython/cython2/' plyvel-$pkgver-py2/Makefile
+}
+
+build() {
+  cd "$srcdir"/plyvel-$pkgver
+  make cython
+  python setup.py build
+
+  cd "$srcdir"/plyvel-$pkgver-py2
+  make cython2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/plyvel-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/plyvel-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-plyvel() {
+  depends=('leveldb' 'python')
+
+  cd plyvel-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.rst
+}
+
+package_python2-plyvel() {
+  depends=('leveldb' 'python2')
+
+  cd plyvel-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE.rst "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.rst
+}