[arch-commits] Commit in blueman/repos (2 files)

[Felix Yan]

    Date: Monday, November 4, 2019 @ 06:35:50
  Author: felixonmars
Revision: 523434

archrelease: copy trunk to community-staging-x86_64

Added:
  blueman/repos/community-staging-x86_64/
  blueman/repos/community-staging-x86_64/PKGBUILD
    (from rev 523433, blueman/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: blueman/repos/community-staging-x86_64/PKGBUILD (from rev 523433, blueman/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-11-04 06:35:50 UTC (rev 523434)
@@ -0,0 +1,46 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Arthur Zamarin <arthurzam at gmail.com>
+# Contributor: Martin Wimpress <code at flexion.org>
+
+pkgname=blueman
+pkgver=2.1.1
+pkgrel=2
+pkgdesc="GTK+ Bluetooth Manager"
+arch=('x86_64')
+url="https://github.com/blueman-project/blueman"
+license=('GPL')
+depends=('bluez' 'bluez-libs' 'gtk3' 'libnm' 'python-cairo' 'python-gobject')
+makedepends=('cython' 'intltool' 'iproute2')
+optdepends=('dnsmasq: Network Access Point (NAP) support'
+            'iproute2: Network Access Point (NAP) support'
+            'networkmanager: Dial Up Networking (DUN) and Personal Area Networking (PAN) support'
+            'pulseaudio-bluetooth: audio devices support')
+source=(https://github.com/blueman-project/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.xz)
+sha256sums=('f1eab2334e5a1587defa80900901048d14c2e8ffa8c0cff7240bc9937a61dbc3')
+
+prepare() {
+  cd $pkgname-$pkgver
+
+  # Fix path for bluetoothd
+  sed -i 's|/usr/sbin/bluetoothd|/usr/lib/bluetooth/bluetoothd|' apps/blueman-report.in
+
+  # Use correct D-Bus config location
+  sed -i '/^dbusdir =/ s/sysconfdir/datadir/' data/configs/Makefile.{am,in}
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --libexecdir=/usr/lib/$pkgname \
+    --disable-schemas-compile \
+    --with-dhcp-config='/etc/dhcpd.conf'
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
+}