[arch-commits] Commit in z3/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Mon Nov 4 07:40:34 UTC 2019
Date: Monday, November 4, 2019 @ 07:40:33
Author: felixonmars
Revision: 523537
archrelease: copy trunk to community-staging-x86_64
Added:
z3/repos/community-staging-x86_64/
z3/repos/community-staging-x86_64/PKGBUILD
(from rev 523536, z3/trunk/PKGBUILD)
----------+
PKGBUILD | 55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 55 insertions(+)
Copied: z3/repos/community-staging-x86_64/PKGBUILD (from rev 523536, z3/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2019-11-04 07:40:33 UTC (rev 523537)
@@ -0,0 +1,55 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: rudy.matela
+
+pkgbase=z3
+pkgname=('z3' 'python-z3')
+pkgver=4.8.6
+pkgrel=2
+pkgdesc='High-performance theorem prover'
+url='https://github.com/Z3Prover/z3'
+arch=('x86_64')
+license=('MIT')
+ # 'java-environment-common' 'mono' 'ocaml' 'ocaml-findlib'
+makedepends=('cmake' 'python' 'python-setuptools' 'gcc-libs' 'gmp')
+source=(https://github.com/Z3Prover/z3/archive/z3-${pkgver}.tar.gz)
+sha512sums=('d338413274a3d11a9e9287202989df9da4c31e095c14428a418d4019e9f86c0e2b681c519d2d0bcbb4cd99a722a2539006f5c86ade568b1ee208545b142369f1')
+
+prepare() {
+ cd ${pkgbase}-z3-${pkgver}
+ mkdir -p build
+}
+
+build() {
+ cd ${pkgbase}-z3-${pkgver}/build
+ cmake .. \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DBUILD_PYTHON_BINDINGS=1 \
+ -DPYTHON_EXECUTABLE=/usr/bin/python \
+ -DUSE_LIB_GMP=1
+ make
+}
+
+package_z3() {
+ depends=('gcc-libs' 'gmp')
+ provides=('libz3' 'libz3.so')
+ cd ${pkgbase}-z3-${pkgver}/build
+ make DESTDIR="${pkgdir}" install
+ install -Dm 644 ../LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
+ rm -r "${pkgdir}"/usr/lib/python*
+}
+
+package_python-z3() {
+ depends=('python' 'libz3')
+ cd ${pkgbase}-z3-${pkgver}/build
+ make DESTDIR="${pkgdir}" install
+ install -Dm 644 ../LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
+ cd "${pkgdir}"
+ rm -r usr/include usr/bin usr/lib/cmake usr/lib/lib*
+ python -m compileall .
+ python -O -m compileall .
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list