[arch-commits] Commit in recoll/repos (2 files)

[Felix Yan]

    Date: Monday, November 4, 2019 @ 07:55:14
  Author: felixonmars
Revision: 523599

archrelease: copy trunk to community-staging-x86_64

Added:
  recoll/repos/community-staging-x86_64/
  recoll/repos/community-staging-x86_64/PKGBUILD
    (from rev 523598, recoll/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: recoll/repos/community-staging-x86_64/PKGBUILD (from rev 523598, recoll/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-11-04 07:55:14 UTC (rev 523599)
@@ -0,0 +1,49 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Vladimir Chizhov <jagoterr at gmail.com>
+# Contributor: Robert Emil Berge <filoktetes at linuxophic.org>
+
+pkgname=recoll
+pkgver=1.25.22
+pkgrel=2
+pkgdesc="Full text search tool based on Xapian backend"
+arch=('x86_64')
+url="https://www.lesbonscomptes.com/recoll/"
+license=('GPL')
+depends=('xapian-core>=1.0.15-1' 'qt5-base' 'openssl' 'hicolor-icon-theme' 'qt5-webkit'
+	 'chmlib')
+makedepends=('python' 'python2-pychm' 'python-setuptools')
+optdepends=('libxslt: for XML based formats (fb2,etc)'
+	    'unzip: for the OpenOffice.org documents'
+	    'poppler: for pdf'
+	    'pstotext: for postscipt'
+	    'antiword: for msword'
+	    'catdoc: for ms excel and powerpoint'
+	    'unrtf: for RTF'
+#	    'untex: for dvi support with dvips'
+	    'djvulibre: for djvu'
+	    'id3lib: for mp3 tags support with id3info'
+	    'python2: for using some filters'
+	    'python2-mutagen: Audio metadata'
+	    'perl-image-exiftool: EXIF data from raw files'
+	    'python-lxml: indexing spreadsheets'
+	    'aspell-en: English stemming support')
+source=("https://www.lesbonscomptes.com/$pkgname/$pkgname-${pkgver/_/}.tar.gz")
+sha256sums=('500d114952aa03c222847df8ecd0f9c58fc1d03b940df72de81e02e52ca905bc')
+
+prepare() {
+  cd "$srcdir/$pkgname-${pkgver/_/}"
+  sed -i '1,1i#include <QAbstractItemView>' qtgui/ssearch_w.cpp
+}
+
+build() {
+  cd "$srcdir/$pkgname-${pkgver/_/}"
+  QMAKE=qmake-qt5 ./configure --prefix=/usr --mandir=/usr/share/man
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname-${pkgver/_/}"
+  make DESTDIR="$pkgdir" install
+}