[arch-commits] Commit in deluge/repos (staging-any staging-any/PKGBUILD)

Felix Yan felixonmars at archlinux.org
Mon Nov 4 08:11:39 UTC 2019


    Date: Monday, November 4, 2019 @ 08:11:37
  Author: felixonmars
Revision: 366697

archrelease: copy trunk to staging-any

Added:
  deluge/repos/staging-any/
  deluge/repos/staging-any/PKGBUILD
    (from rev 366696, deluge/trunk/PKGBUILD)

----------+
 PKGBUILD |   87 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 87 insertions(+)

Copied: deluge/repos/staging-any/PKGBUILD (from rev 366696, deluge/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2019-11-04 08:11:37 UTC (rev 366697)
@@ -0,0 +1,87 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Hugo Doria <hugo at archlinux.org>
+
+pkgname=deluge
+pkgver=2.0.3
+pkgrel=2
+pkgdesc="A BitTorrent client with multiple user interfaces in a client/server model"
+arch=(any)
+url="https://deluge-torrent.org/"
+license=(GPL3)
+depends=(
+  # Follows DEPENDS.md
+  'python-twisted>=17.1' python-service-identity python-idna
+  'openssl>=1.0.1'
+  python-pyopenssl
+  'python-rencode>=1.0.2'
+  python-xdg
+  xdg-utils
+  python-six
+  'python-zope-interface>=4.4.2' 
+  python-chardet 
+  python-setproctitle 
+  python-pillow
+  python-dbus
+  python-distro
+  'libtorrent-rasterbar>=1.1.1'
+  python-geoip
+  python-mako
+)
+makedepends=(
+  python-setuptools
+  intltool
+  gtk3
+  python-gobject
+  python-cairo
+  librsvg
+  libappindicator-gtk3
+  #python-pygame
+  libnotify
+  git
+)
+optdepends=(
+  'gtk3: gtk ui'
+  'python-gobject: gtk ui'
+  'python-cairo: gtk ui'
+  'librsvg: gtk ui'
+  'libappindicator-gtk3: appindicator notifications'
+  #'python-pygame: audible notifications'
+  'libnotify: desktop notifications'
+)
+_commit=b711cd258ae3001d5f1aa69617c22a2d258b1c06  # tags/deluge-2.0.3^0
+source=("git://git.deluge-torrent.org/deluge.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe | sed 's/^deluge-//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  cd $pkgname
+  python setup.py build
+}
+
+package() {
+  cd $pkgname
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  install -Dt "$pkgdir/usr/lib/systemd/system" \
+    -m644 packaging/systemd/*.service
+  install -Dt "$pkgdir/usr/lib/systemd/system/deluged.service.d" \
+    -m644 packaging/systemd/user.conf
+  install -Dt "$pkgdir/usr/lib/systemd/system/deluge-web.service.d" \
+    -m644 packaging/systemd/user.conf
+
+  echo 'u deluge - "Deluge BitTorrent daemon" /srv/deluge' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
+  echo 'd /srv/deluge 0770 deluge deluge' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
+}
+
+# vim:set sw=2 et:



More information about the arch-commits mailing list