[arch-commits] Commit in python-pplpy/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Mon Nov 4 08:42:37 UTC 2019
Date: Monday, November 4, 2019 @ 08:42:36
Author: felixonmars
Revision: 523794
archrelease: copy trunk to community-staging-x86_64
Added:
python-pplpy/repos/community-staging-x86_64/
python-pplpy/repos/community-staging-x86_64/PKGBUILD
(from rev 523793, python-pplpy/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: python-pplpy/repos/community-staging-x86_64/PKGBUILD (from rev 523793, python-pplpy/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2019-11-04 08:42:36 UTC (rev 523794)
@@ -0,0 +1,50 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+_pipname=pplpy
+pkgbase=python-pplpy
+pkgname=(python2-pplpy python-pplpy pplpy-doc)
+pkgver=0.8.4
+pkgrel=4
+pkgdesc="Python wrapper to the C++ Parma Polyhedra Library (PPL)"
+arch=(x86_64)
+url="https://gitlab.com/videlec/pplpy/"
+license=(LGPL2.1)
+makedepends=(cython2 cython python-cysignals python2-cysignals python-gmpy2 python2-gmpy2 ppl python-sphinx)
+source=("https://pypi.io/packages/source/${_pipname:0:1}/$_pipname/$_pipname-$pkgver.tar.gz")
+sha256sums=('b962914d5814edab320d00c11ca396b70c4ce1e67db7a6d59c4b0a3772a16836')
+
+prepare() {
+ cp -r $_pipname-$pkgver{,-py2}
+}
+
+build() {
+ cd $_pipname-$pkgver-py2
+ python2 setup.py build
+
+ cd ../$_pipname-$pkgver
+ python setup.py build
+
+ _pythonver=`python -c "from sysconfig import get_python_version; print(get_python_version())"`
+ PYTHONPATH="$PWD/build/lib.linux-x86_64-$_pythonver" make -C docs html
+}
+
+package_python2-pplpy() {
+ depends=(python2-cysignals python2-gmpy2 ppl)
+
+ cd $_pipname-$pkgver-py2
+ python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}
+
+package_python-pplpy() {
+ depends=(python-cysignals python-gmpy2 ppl)
+
+ cd $_pipname-$pkgver
+ python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}
+
+package_pplpy-doc() {
+ pkgdesc="HTML documentation for pplpy"
+
+ mkdir -p "$pkgdir"/usr/share/doc/pplpy
+ cp -r $_pipname-$pkgver/docs/build/html/* "$pkgdir"/usr/share/doc/pplpy
+}
More information about the arch-commits
mailing list