[arch-commits] Commit in python-netcdf4/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 4, 2019 @ 09:19:20
  Author: foutrelis
Revision: 523860

archrelease: copy trunk to community-staging-x86_64

Added:
  python-netcdf4/repos/community-staging-x86_64/
  python-netcdf4/repos/community-staging-x86_64/PKGBUILD
    (from rev 523859, python-netcdf4/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: python-netcdf4/repos/community-staging-x86_64/PKGBUILD (from rev 523859, python-netcdf4/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-11-04 09:19:20 UTC (rev 523860)
@@ -0,0 +1,60 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Spyros Stathopoulos <foucault.online at gmail.com>
+# Contributor: richli <rich at dranek dot com>
+# Contributor: rememberthemer <rememberthemer at _GMAIL_DOT_COM_>
+
+_pkg=netCDF4
+pkgbase=python-${_pkg,,}
+pkgname=("python-${_pkg,,}" "python2-${_pkg,,}")
+pkgver=1.5.3
+pkgrel=2
+pkgdesc="Python/NumPy interface to the netCDF C library"
+arch=(x86_64)
+url="https://unidata.github.io/netcdf4-python"
+license=(MIT)
+makedepends=(cython python-setuptools cython2 python2-setuptools python-numpy python-cftime python2-numpy python2-cftime netcdf)
+source=("https://files.pythonhosted.org/packages/source/n/${_pkg}/${_pkg}-${pkgver}.tar.gz")
+sha256sums=('2a3ca855848f4bbf07fac366da77a681fcead18c0a8813d91d46302f562dc3be')
+
+prepare() {
+    cp -a ${_pkg}-${pkgver}{,-py2}
+}
+
+build() {
+    cd ${_pkg}-${pkgver}
+    USE_NCCONFIG=1 python setup.py build
+
+    cd ../${_pkg}-${pkgver}-py2
+    USE_NCCONFIG=1 python2 setup.py build
+}
+
+check() {
+    cd ${_pkg}-${pkgver}/test
+    PYTHONPATH="../build/lib.linux-${CARCH}-3.8" python -B ./run_all.py
+
+    cd ../../${_pkg}-${pkgver}-py2/test
+    PYTHONPATH="../build/lib.linux-${CARCH}-2.7" python2 -B ./run_all.py
+}
+
+package_python-netcdf4() {
+    depends=(python-numpy python-cftime netcdf)
+
+    cd ${_pkg}-${pkgver}
+    USE_NCCONFIG=1 python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=2
+
+    install -Dm644 docs/netCDF4/* -t "${pkgdir}"/usr/share/doc/${pkgname}/docs/netCDF4
+    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
+
+package_python2-netcdf4() {
+    depends=(python2-numpy python2-cftime netcdf)
+
+    cd ${_pkg}-${pkgver}-py2
+    USE_NCCONFIG=1 python2 setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=2
+
+    for binary in "${pkgdir}"/usr/bin/* ;
+        do mv ${binary}{,-py2} ;
+    done
+    install -Dm644 docs/netCDF4/* -t "${pkgdir}"/usr/share/doc/${pkgname}/docs/netCDF4
+    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}