[arch-commits] Commit in python-xapian/repos (2 files)

Felix Yan felixonmars at archlinux.org
Mon Nov 4 09:21:50 UTC 2019


    Date: Monday, November 4, 2019 @ 09:21:48
  Author: felixonmars
Revision: 523866

archrelease: copy trunk to community-staging-x86_64

Added:
  python-xapian/repos/community-staging-x86_64/
  python-xapian/repos/community-staging-x86_64/PKGBUILD
    (from rev 523865, python-xapian/trunk/PKGBUILD)

----------+
 PKGBUILD |   64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

Copied: python-xapian/repos/community-staging-x86_64/PKGBUILD (from rev 523865, python-xapian/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-11-04 09:21:48 UTC (rev 523866)
@@ -0,0 +1,64 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: David Runge <dave at sleepmap.de>
+# Contributor: DonVla <donvla/users.sourceforge/net>
+# Contributor: Hervé Cauwelier <herve/oursours/net>
+
+pkgbase=python-xapian
+pkgname=('python-xapian' 'python2-xapian')
+_realname=xapian-bindings
+pkgver=1.4.13
+epoch=1
+pkgrel=2
+pkgdesc="Python bindings for Xapian"
+arch=('x86_64')
+url="https://xapian.org/docs/bindings/python/"
+license=('GPL2')
+makedepends=('python-sphinx' 'python2-sphinx' "xapian-core=$epoch:$pkgver")
+source=("https://oligarchy.co.uk/xapian/${pkgver}/${_realname}-${pkgver}.tar.xz"{,.asc})
+sha512sums=('20f5f8842e401ba1c1407f336d1a03fa8bc6faa1fcc9533bad1772644ad3ae878a51f10c2f7810f89e3f14683a73c0c089601af548cdf3fbe7feeead4d2d21d9'
+            'SKIP')
+validpgpkeys=('08E2400FF7FE8FEDE3ACB52818147B073BAD2B07') # Olly Betts <olly at debian.org>
+
+prepare() {
+  cd "${_realname}-${pkgver}"
+  autoreconf -vfi
+  cd ..
+  mv -v "${_realname}-$pkgver" "${pkgname[0]}-${pkgver}"
+  cp -av "${pkgname[0]}-$pkgver" "${pkgname[1]}-${pkgver}"
+  cd "${pkgname[1]}-${pkgver}"
+  # fix shebang of examples
+  sed -i '1s/python/python2/' python/docs/examples/*.py
+  export XAPIAN_CONFIG=/usr/bin/xapian-config
+}
+
+build() {
+  cd "${pkgname[0]}-${pkgver}"
+  ./configure --prefix=/usr \
+              --with-python3
+  make
+  cd ../"${pkgname[1]}-${pkgver}"
+  PYTHON2=/usr/bin/python2
+  ./configure --prefix=/usr \
+              --with-python
+  make
+}
+
+package_python-xapian() {
+  pkgdesc="Python 3.x bindings for Xapian"
+  depends=('python' "xapian-core=$epoch:$pkgver")
+  cd "${pkgname[0]}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+  install -t "${pkgdir}/usr/share/doc/${pkgname[0]}" \
+    -vDm644 {AUTHORS,ChangeLog,HACKING,NEWS,README,TODO}
+}
+
+package_python2-xapian() {
+  pkgdesc="Python 2.x bindings for Xapian"
+  depends=('python2' "xapian-core=$epoch:$pkgver")
+  cd "${pkgname[1]}-${pkgver}"
+  make DESTDIR="$pkgdir" install
+  install -t "${pkgdir}/usr/share/doc/${pkgname[1]}" \
+    -vDm644 {AUTHORS,ChangeLog,HACKING,NEWS,README,TODO}
+}
+
+# vim:set ts=2 sw=2 et:



More information about the arch-commits mailing list