[arch-commits] Commit in beets/repos (3 files)

[Felix Yan]

    Date: Monday, November 4, 2019 @ 09:31:24
  Author: felixonmars
Revision: 523904

archrelease: copy trunk to community-staging-any

Added:
  beets/repos/community-staging-any/
  beets/repos/community-staging-any/PKGBUILD
    (from rev 523902, beets/trunk/PKGBUILD)
  beets/repos/community-staging-any/beet
    (from rev 523902, beets/trunk/beet)

----------+
 PKGBUILD |   74 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 beet     |    2 +
 2 files changed, 76 insertions(+)

Copied: beets/repos/community-staging-any/PKGBUILD (from rev 523902, beets/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-11-04 09:31:24 UTC (rev 523904)
@@ -0,0 +1,74 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Adrian Sampson <adrian at radbox.org>
+
+pkgname=beets
+pkgver=1.4.9
+pkgrel=2
+pkgdesc='Flexible music library manager and tagger'
+arch=(any)
+url=https://beets.io/
+license=(MIT)
+depends=(
+  python-jellyfish
+  python-munkres
+  python-musicbrainzngs
+  python-mutagen
+  python-setuptools
+  python-six
+  python-unidecode
+  python-yaml
+)
+makedepends=(
+  git
+  python-sphinx
+)
+optdepends=(
+  'bash-completion: Bash completion'
+  'bs1770gain: ReplayGain plugin'
+  'gst-plugins-bad: Chromaprint/Acoustid, BPD, ReplayGain plugins'
+  'gst-plugins-good: Chromaprint/Acoustid, BPD, ReplayGain plugins'
+  'gst-plugins-ugly: Chromaprint/Acoustid, BPD, ReplayGain plugins'
+  'gst-libav: Chromaprint/Acoustid, BPD, ReplayGain plugins'
+  'gst-python: Chromaprint/Acoustid, BPD, ReplayGain plugins'
+  'imagemagick: Thumbnails plugin'
+  'python-beautifulsoup4: Lyrics plugin'
+  'python-flask: Web plugin'
+  'python-gobject: ReplayGain plugin'
+  'python-mpd2: MPDStats plugin'
+  'python-pyacoustid: Chromaprint/Acoustid plugin'
+  'python-pylast: LastGenre plugin'
+  'python-requests: Chromaprint/Acoustid, BPD, FetchArt plugins'
+  'python-xdg: Thumbnails plugin'
+)
+source=(
+  git+https://github.com/beetbox/beets.git#tag=v${pkgver}
+  beet
+)
+sha256sums=('SKIP'
+            'b081285b202f82d09802ebca73d28bbf1902179ad3a820e4c0157f80bf959d89')
+
+build() {
+  cd beets
+
+  python setup.py build sdist
+}
+
+package() {
+  cd beets
+
+  python setup.py install --root="${pkgdir}" --optimize=1
+
+  install -dm 755 "${pkgdir}"/usr/share/bash-completion/completions/
+  install -m 644 ../beet "${pkgdir}"/usr/share/bash-completion/completions/
+  install -dm 755 "${pkgdir}"/usr/share/zsh/site-functions
+  install -m 644 extra/_beet "${pkgdir}"/usr/share/zsh/site-functions/
+
+  install -dm 755 "${pkgdir}"/usr/share/man/man{1,5}
+  install -m 644 man/beet.1 "${pkgdir}"/usr/share/man/man1/
+  install -m 644 man/beetsconfig.5 "${pkgdir}"/usr/share/man/man5/
+
+  install -dm 755 "${pkgdir}"/usr/share/licenses/beets
+  install -m 644 LICENSE "${pkgdir}"/usr/share/licenses/beets/
+}
+
+# vim: ts=2 sw=2 et:

Copied: beets/repos/community-staging-any/beet (from rev 523902, beets/trunk/beet)
===================================================================
--- community-staging-any/beet	                        (rev 0)
+++ community-staging-any/beet	2019-11-04 09:31:24 UTC (rev 523904)
@@ -0,0 +1,2 @@
+_load_beet_completion() { eval "$(beet completion)"; }
+complete -F _load_beet_completion beet