[arch-commits] Commit in python-pyxattr/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 4, 2019 @ 10:47:15
  Author: foutrelis
Revision: 524031

archrelease: copy trunk to community-staging-x86_64

Added:
  python-pyxattr/repos/community-staging-x86_64/
  python-pyxattr/repos/community-staging-x86_64/PKGBUILD
    (from rev 524030, python-pyxattr/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: python-pyxattr/repos/community-staging-x86_64/PKGBUILD (from rev 524030, python-pyxattr/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-11-04 10:47:15 UTC (rev 524031)
@@ -0,0 +1,57 @@
+# Maintainer: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: Jon Bergli Heier <snakebite at jvnv.net>
+
+pkgname=('python2-pyxattr' 'python-pyxattr')
+pkgbase=python-pyxattr
+_pkgname=pyxattr
+pkgver=0.6.0
+pkgrel=3
+pkgdesc='A python extension module that allows you to manipulate the extended attributes.'
+arch=('x86_64')
+url='https://pyxattr.k1024.org/'
+license=('GPL')
+makedepends=('python2' 'python' 'python2-setuptools' 'python-setuptools')
+source=("https://pyxattr.k1024.org/downloads/pyxattr-$pkgver.tar.gz"{,.asc}
+        "pyxattr-xattr-2.4.48.patch::https://github.com/iustin/pyxattr/pull/15.patch")
+md5sums=('3e2f9dd92459a0fe0d02861dff4c2f4d'
+         'SKIP'
+         '00dbdc4c8ca4638356e57751ad164591')
+validpgpkeys=('CB94E3AA3B1755D61EBB19A5F66E3E419F84F4DE') # Iustin Pop <iustin at k1024.org>
+
+prepare() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+
+  # https://github.com/iustin/pyxattr/pull/15
+  patch -p1 -i ../pyxattr-xattr-2.4.48.patch
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+
+  python setup.py build
+  python2 setup.py build
+}
+
+check() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+
+  python setup.py test
+  python2 setup.py test
+}
+
+package_python2-pyxattr() {
+  depends=('python2')
+  provides=('pyxattr')
+  conflicts=('pyxattr')
+  replaces=('pyxattr')
+
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  python2 setup.py install --root="${pkgdir}"
+}
+
+package_python-pyxattr() {
+  depends=('python')
+
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  python setup.py install --root="${pkgdir}"
+}