[arch-commits] Commit in gnome-builder/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Monday, November 4, 2019 @ 20:41:51
  Author: felixonmars
Revision: 366763

archrelease: copy trunk to staging-x86_64

Added:
  gnome-builder/repos/staging-x86_64/
  gnome-builder/repos/staging-x86_64/PKGBUILD
    (from rev 366762, gnome-builder/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: gnome-builder/repos/staging-x86_64/PKGBUILD (from rev 366762, gnome-builder/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-11-04 20:41:51 UTC (rev 366763)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-builder
+pkgver=3.34.1
+pkgrel=3
+pkgdesc="An IDE for writing GNOME-based software"
+url="https://wiki.gnome.org/Apps/Builder"
+arch=(x86_64)
+license=(GPL3)
+depends=(gtksourceview4 devhelp libgit2-glib gjs python-gobject clang desktop-file-utils ctags
+         libpeas vte3 vala python-jedi autoconf-archive sysprof flatpak-builder gspell libdazzle
+         template-glib jsonrpc-glib python-sphinx webkit2gtk glade python-lxml meson)
+makedepends=(llvm gobject-introspection gtk-doc yelp-tools appstream-glib git mm-common
+             python-sphinx_rtd_theme)
+checkdepends=(xorg-server-xvfb)
+optdepends=('gnome-code-assistance: Legacy assistance services')
+groups=(gnome-extra)
+_commit=f28549a6e8dc326b7f29eaa5b0fc29e4050f4b75  # tags/3.34.1^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-builder.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^GNOME_BUILDER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git cherry-pick -n c8b862b491cfbbb4f79b24d7cd90e4fb1f37cb9f # Fix build with meson 0.52
+  git cherry-pick -n da26dfbf78468f5ed724e022b300a07862a95833
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D docs=true \
+    -D help=true
+  ninja -C build
+}
+
+check() {
+  xvfb-run meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set sw=2 et: