[arch-commits] Commit in radare2-cutter/repos (2 files)

[Felix Yan]

    Date: Wednesday, November 6, 2019 @ 22:35:30
  Author: felixonmars
Revision: 524430

archrelease: copy trunk to community-staging-x86_64

Added:
  radare2-cutter/repos/community-staging-x86_64/
  radare2-cutter/repos/community-staging-x86_64/PKGBUILD
    (from rev 524429, radare2-cutter/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: radare2-cutter/repos/community-staging-x86_64/PKGBUILD (from rev 524429, radare2-cutter/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-11-06 22:35:30 UTC (rev 524430)
@@ -0,0 +1,48 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Santiago Torres-Arias <santiago[at]archlinux[dot]org>
+# Contributor: Aaron McDaniel (mcd1992) <'aur' at the domain 'fgthou.se'>
+
+pkgname=radare2-cutter
+_gitcommit=b4535227cf1ebfb94da40c950215512acbcbb9bf
+pkgver=1.9.0
+epoch=1
+pkgrel=4
+pkgdesc='Qt and C++ GUI for radare2 reverse engineering framework'
+url='https://github.com/radareorg/cutter'
+arch=('x86_64')
+license=('GPL3')
+depends=('radare2' 'capstone' 'qt5-base' 'qt5-svg' 'qt5-webengine' 'icu' 'python' 'jupyter'
+         'pyside2' 'shiboken2' 'python-shiboken2')
+makedepends=('git' 'cmake')
+source=(${pkgname}::"git+https://github.com/radareorg/cutter#commit=${_gitcommit}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd ${pkgname}
+  git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  sed -e 's|PKGCONFIG += python3|PKGCONFIG += python3-embed|' -i $pkgname/src/Cutter.pro # Fix linking to python 3.8
+}
+
+build() {
+  mkdir -p ${pkgname}/build
+  cd ${pkgname}/build
+  qmake ../src/Cutter.pro \
+    CUTTER_ENABLE_PYTHON=true \
+    CUTTER_ENABLE_PYTHON_BINDINGS=true \
+    CUTTER_USE_BUNDLED_RADARE2=false
+  make
+}
+
+package() {
+  cd ${pkgname}
+  install -Dm 755 build/Cutter -t "${pkgdir}/usr/bin"
+  install -Dm 644 src/org.radare.Cutter.desktop -t "${pkgdir}/usr/share/applications"
+  install -Dm 644 src/img/cutter.svg -t "${pkgdir}/usr/share/icons/hicolor/scalable/apps"
+  install -d "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -a docs/* "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: