[arch-commits] Commit in (pragha pragha/trunk pragha/trunk/PKGBUILD)

[Konstantin Gizdov]

    Date: Saturday, November 9, 2019 @ 08:53:57
  Author: kgizdov
Revision: 524788

re-publish pragha

Added:
  pragha/
  pragha/trunk/
  pragha/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: pragha/trunk/PKGBUILD
===================================================================
--- pragha/trunk/PKGBUILD	                        (rev 0)
+++ pragha/trunk/PKGBUILD	2019-11-09 08:53:57 UTC (rev 524788)
@@ -0,0 +1,45 @@
+# Maintainer: Konstantin Gizdov <arch at kge.pw>
+# Contributor: Alad Wenter <alad at archlinux.org>
+# Contributor: Thorsten Töpper <atsutane-tu at freethoughts.de>
+# Contributor: J0k3r <moebius282 e4a t gmail D0_T com>
+# Contributor: Alois Nespor <alois.nespor at gmail.com>
+# Contributor: JerichoKru   <jerichokru(AT)hotmail.com>
+
+pkgname=pragha
+pkgver=1.3.4
+pkgrel=2
+pkgdesc="A lightweight GTK+ music manager - fork of Consonance Music Manager."
+arch=('x86_64')
+url="https://pragha-music-player.github.io/"
+license=('GPL3')
+depends=('libnotify' 'libcdio-paranoia' 'libclastfm' 'gst-plugins-base'
+         'taglib' 'hicolor-icon-theme' 'dbus-glib' 'desktop-file-utils'
+         'libpeas' 'libgudev' 'glyr')
+optdepends=('gst-plugins-good: A collection of gstreamer codecs'
+            'gst-plugins-bad: A collection of gstreamer codecs'
+            'gst-plugins-ugly: A collection of gstreamer codecs')
+makedepends=('intltool' 'xfce4-dev-tools' 'gobject-introspection')
+replaces=('dissonance')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/pragha-music-player/pragha/archive/v$pkgver.tar.gz")
+sha256sums=('8be35959f526d079cc19221653cb691fb66251e6819f994062e0b02e08b1809b')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  ./autogen.sh
+
+  CPPFLAGS="${CPPFLAGS} -DHAVE_PARANOIA_NEW_INCLUDES" \
+  LIBS="${LIBS} -ldbus-glib-1" \
+    ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}/" install
+
+  install -m 644 "data/${pkgname}.desktop" "${pkgdir}/usr/share/applications"
+  install -d "${pkgdir}/usr/share/pixmaps"
+  install -m 644 "data/${pkgname}.1" "${pkgdir}/usr/share/man/man1/"
+}
+
+# vim:ts=2:sw=2:expandtab