[arch-commits] Commit in ogre/repos/community-staging-x86_64 (4 files)

[Sven-Hendrik Haase]

    Date: Saturday, November 9, 2019 @ 14:37:48
  Author: svenstaro
Revision: 524833

archrelease: copy trunk to community-staging-x86_64

Added:
  ogre/repos/community-staging-x86_64/PKGBUILD
    (from rev 524832, ogre/trunk/PKGBUILD)
  ogre/repos/community-staging-x86_64/ogre.install
    (from rev 524832, ogre/trunk/ogre.install)
Deleted:
  ogre/repos/community-staging-x86_64/PKGBUILD
  ogre/repos/community-staging-x86_64/ogre.install

--------------+
 PKGBUILD     |  118 ++++++++++++++++++++++++---------------------------------
 ogre.install |    6 +-
 2 files changed, 54 insertions(+), 70 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2019-11-09 14:37:38 UTC (rev 524832)
+++ PKGBUILD	2019-11-09 14:37:48 UTC (rev 524833)
@@ -1,67 +0,0 @@
-# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
-pkgbase=ogre
-pkgname=('ogre' 'ogre-docs')
-pkgver=1.12.2
-pkgrel=3
-pkgdesc='Scene-oriented, flexible 3D engine written in C++'
-arch=('x86_64')
-url='http://www.ogre3d.org'
-license=('custom:MIT')
-depends=('freeimage' 'freetype2' 'libxaw' 'libxrandr' 'openexr' 'pugixml'
-         'nvidia-cg-toolkit' 'zziplib' 'sdl2' 'glu' 'tinyxml')
-makedepends=('cmake' 'doxygen' 'graphviz' 'ttf-dejavu' 'mesa' 'python' 'swig' 'systemd')
-install=ogre.install
-source=("https://github.com/OGRECave/ogre/archive/v${pkgver}.tar.gz")
-sha512sums=('557a9ca85f5ac5a41ff7ef06622723e04b008f3e9dc90d44b13ed05f34b5bf23cf9a1959d94d34a12dc0750eeb3b4550d62ba5102379d1b2825753b2b0a836d7')
-
-prepare() {
-  mkdir ogre-${pkgver}/build
-}
-
-build() {
-  cd ogre-${pkgver}/build
-
-  cmake .. \
-    -DCMAKE_INSTALL_PREFIX=/usr \
-    -DOGRE_BUILD_DEPENDENCIES=FALSE \
-    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
-    -DOGRE_BUILD_PLUGIN_FREEIMAGE=TRUE \
-    -DOGRE_BUILD_PLUGIN_EXRCODEC=TRUE
-
-  make
-  make OgreDoc
-}
-
-package_ogre() {
-  optdepends=('cppunit: unit testing'
-              'python: python bindings'
-              'ogre-docs: documentation')
-
-  cd ogre-${pkgver}/build
-
-  make DESTDIR=${pkgdir} install
-
-  mv ${pkgdir}/usr/bin/SampleBrowser ${pkgdir}/usr/bin/OgreSampleBrowser
-  install -Dm644 ../LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
-
-  # move docs out of this package
-  mv ${pkgdir}/usr/share/OGRE/docs ${srcdir}/docs
-}
-
-package_ogre-docs() {
-  pkgdesc="Documentation for ogre"
-  depends=()
-
-  cd ogre-${pkgver}/build
-
-  # move docs into this package
-  install -dm755 ${pkgdir}/usr/share/doc
-  mv ${srcdir}/docs ${pkgdir}/usr/share/doc/OGRE/
-
-  # symlink for docs
-  install -dm755 ${pkgdir}/usr/share/OGRE/
-  cd ${pkgdir}/usr/share
-  ln -s /usr/share/doc/OGRE/ OGRE/docs
-}
-
-# vim:set ts=2 sw=2 et:

Copied: ogre/repos/community-staging-x86_64/PKGBUILD (from rev 524832, ogre/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-11-09 14:37:48 UTC (rev 524833)
@@ -0,0 +1,51 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+pkgname=ogre
+pkgver=1.12.3
+pkgrel=2
+pkgdesc='Scene-oriented, flexible 3D engine written in C++'
+arch=('x86_64')
+url='http://www.ogre3d.org'
+license=('custom:MIT')
+depends=('freeimage' 'freetype2' 'libxaw' 'libxrandr' 'openexr' 'pugixml'
+         'nvidia-cg-toolkit' 'zziplib' 'sdl2' 'glu' 'tinyxml')
+makedepends=('cmake' 'doxygen' 'graphviz' 'ttf-dejavu' 'mesa' 'python' 'swig' 'systemd' 'git')
+install=ogre.install
+replaces=('ogre-docs')
+source=("https://github.com/OGRECave/ogre/archive/v${pkgver}.tar.gz"
+        "git+https://github.com/ocornut/imgui.git#commit=688cf868ea83db6c2958dd6bf7a20d471d00940b")
+optdepends=('cppunit: unit testing'
+            'python: python bindings')
+sha512sums=('1381b342e763f006952e8b2cf70e129f0e4ac399495450a72b2d9a97f39fd4346897b83e9acaa47611c1d5c8565cc6b5b5f1b516078a8904afa1c9e73188b586'
+            'SKIP')
+
+prepare() {
+  mkdir ogre-${pkgver}/build
+
+  cp -r "$srcdir"/imgui ogre-${pkgver}/Components/Overlay/src/
+}
+
+build() {
+  cd ogre-${pkgver}/build
+
+  cmake .. \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DOGRE_BUILD_DEPENDENCIES=FALSE \
+    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
+    -DOGRE_BUILD_PLUGIN_FREEIMAGE=TRUE \
+    -DOGRE_BUILD_PLUGIN_EXRCODEC=TRUE
+
+  make
+  make OgreDoc
+}
+
+package() {
+
+  cd ogre-${pkgver}/build
+
+  make DESTDIR=${pkgdir} install
+
+  mv ${pkgdir}/usr/bin/SampleBrowser ${pkgdir}/usr/bin/OgreSampleBrowser
+  install -Dm644 ../LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:

Deleted: ogre.install
===================================================================
--- ogre.install	2019-11-09 14:37:38 UTC (rev 524832)
+++ ogre.install	2019-11-09 14:37:48 UTC (rev 524833)
@@ -1,3 +0,0 @@
-post_install() {
-    echo "To view the OGRE samples just run OgreSampleBrowser"
-}

Copied: ogre/repos/community-staging-x86_64/ogre.install (from rev 524832, ogre/trunk/ogre.install)
===================================================================
--- ogre.install	                        (rev 0)
+++ ogre.install	2019-11-09 14:37:48 UTC (rev 524833)
@@ -0,0 +1,3 @@
+post_install() {
+    echo "To view the OGRE samples just run OgreSampleBrowser"
+}