[arch-commits] Commit in spirv-llvm-translator/repos (2 files)

[Daniel Bermond]

    Date: Sunday, November 10, 2019 @ 18:56:17
  Author: dbermond
Revision: 526486

archrelease: copy trunk to community-testing-x86_64

Added:
  spirv-llvm-translator/repos/community-testing-x86_64/
  spirv-llvm-translator/repos/community-testing-x86_64/PKGBUILD
    (from rev 526485, spirv-llvm-translator/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: spirv-llvm-translator/repos/community-testing-x86_64/PKGBUILD (from rev 526485, spirv-llvm-translator/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-11-10 18:56:17 UTC (rev 526486)
@@ -0,0 +1,38 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+
+_srcname=SPIRV-LLVM-Translator
+pkgname=${_srcname,,}
+_build=1
+pkgver=9.0.0.${_build}
+pkgrel=2
+pkgdesc="Tool and a library for bi-directional translation between SPIR-V and LLVM IR"
+arch=(x86_64)
+url="https://github.com/KhronosGroup/SPIRV-LLVM-Translator/"
+license=(custom)
+makedepends=(cmake llvm)
+source=("${url}/archive/v${pkgver%.*}-${_build}/${pkgname}-${pkgver}.tar.gz")
+sha256sums=('19eff5daedb2c1aac8ab8d64a9f8228976dbaad71b1c1a3d3cd4c17cccdb0e55')
+
+prepare() {
+    mkdir -p build
+}
+
+build() {
+    cd build
+    
+    # workaround to fix luxmark crashing issue: use -O0
+    # https://github.com/intel/compute-runtime/issues/218
+    cmake ../${_srcname}-${pkgver%.*}-${_build} \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_CXX_FLAGS_RELEASE='-O0' \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_POSITION_INDEPENDENT_CODE=ON \
+        -Wno-dev
+    make
+}
+
+package() {
+    cd build
+    make DESTDIR="${pkgdir}" install
+    install -Dm644 ../${_srcname}-${pkgver%.*}-${_build}/LICENSE.TXT -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}