[arch-commits] Commit in texworks/repos (2 files)

[Evangelos Foutras]

    Date: Sunday, November 10, 2019 @ 20:13:36
  Author: foutrelis
Revision: 526508

archrelease: copy trunk to community-staging-x86_64

Added:
  texworks/repos/community-staging-x86_64/
  texworks/repos/community-staging-x86_64/PKGBUILD
    (from rev 526507, texworks/trunk/PKGBUILD)

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Copied: texworks/repos/community-staging-x86_64/PKGBUILD (from rev 526507, texworks/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-11-10 20:13:36 UTC (rev 526508)
@@ -0,0 +1,36 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+pkgname=texworks
+pkgver=0.6.3
+pkgrel=5
+pkgdesc='Unicode-based, TeX-aware editor with integrated PDF viewer'
+arch=('x86_64')
+url='https://www.tug.org/texworks/'
+license=('GPL')
+depends=('hunspell' 'poppler-qt5' 'qt5-script')
+makedepends=('cmake' 'lua' 'python' 'qt5-tools')
+checkdepends=('gsfonts' 'poppler-data' 'xorg-server-xvfb')
+optdepends=('gsfonts: correctly display PDF files without embedded fonts'
+            'lua: Lua scripts support'
+            'poppler-data: correctly display certain CJK documents'
+            'python: Python scripts support'
+            'texlive-core: typeset TeX documents')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/TeXworks/texworks/archive/release-$pkgver.tar.gz")
+sha512sums=('389cf54441e74164fc842f2f293cdee45c6ff9fe202f262d32f3fb076de9a29813a62cd75052969293f2f784e0722215bbbf2206e75bc836a13d495bf5aed653')
+
+build() {
+	cd "texworks-release-$pkgver"
+	mkdir build
+	cd build
+	cmake -DCMAKE_INSTALL_PREFIX=/usr -DTW_BUILD_ID='Arch Linux' -DWITH_PYTHON=ON ..
+	make
+}
+
+check() {
+	cd "texworks-release-$pkgver/build"
+	xvfb-run ctest --output-on-failure
+}
+
+package() {
+	cd "texworks-release-$pkgver/build"
+	make DESTDIR="$pkgdir" install
+}