[arch-commits] Commit in ibus-typing-booster/repos (staging-any staging-any/PKGBUILD)

[Felix Yan]

    Date: Sunday, November 10, 2019 @ 20:14:49
  Author: felixonmars
Revision: 367694

archrelease: copy trunk to staging-any

Added:
  ibus-typing-booster/repos/staging-any/
  ibus-typing-booster/repos/staging-any/PKGBUILD
    (from rev 367693, ibus-typing-booster/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: ibus-typing-booster/repos/staging-any/PKGBUILD (from rev 367693, ibus-typing-booster/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2019-11-10 20:14:49 UTC (rev 367694)
@@ -0,0 +1,38 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=ibus-typing-booster
+pkgver=2.7.2
+pkgrel=2
+pkgdesc="Predictive input method for the IBus platform"
+url="https://mike-fabian.github.io/ibus-typing-booster/"
+arch=(any)
+license=(GPL3 Apache)
+depends=(ibus python-gobject python-dbus python-pyenchant m17n-lib sqlite)
+makedepends=(git)
+_commit=d9c4539e8eb974bae5cca8364f96d25deedb4cf2  # tags/2.7.2
+source=("git+https://github.com/mike-fabian/ibus-typing-booster#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  autoreconf -fvi
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --libexec=/usr/lib/ibus
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+
+  cd "$pkgdir/usr/share/$pkgname/data"
+  gzip -nf --best *.{txt,json} annotations{,Derived}/*.xml
+}