[arch-commits] Commit in handbrake/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Evangelos Foutras]

    Date: Monday, November 11, 2019 @ 00:23:39
  Author: foutrelis
Revision: 526602

archrelease: copy trunk to community-x86_64

Added:
  handbrake/repos/community-x86_64/PKGBUILD
    (from rev 526601, handbrake/trunk/PKGBUILD)
Deleted:
  handbrake/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |  108 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 54 insertions(+), 54 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2019-11-11 00:23:32 UTC (rev 526601)
+++ PKGBUILD	2019-11-11 00:23:39 UTC (rev 526602)
@@ -1,54 +0,0 @@
-# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
-# Contributor: Giovanni Scafora <giovanni at archlinux.org>
-# Contributor: Sebastien Piccand <sebcactus gmail com>
-
-pkgname=('handbrake' 'handbrake-cli')
-pkgver=1.2.2
-pkgrel=2
-arch=('x86_64')
-url="https://handbrake.fr/"
-license=('GPL')
-makedepends=('intltool' 'python2' 'nasm' 'wget' 'cmake' 'bzip2' 'gcc-libs' 'xz'
-             'zlib' 'libnotify' 'gst-plugins-base' 'gtk3' 'dbus-glib' 'libass'
-             'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora' 'libsamplerate'
-             'speex' 'x264' 'jansson' 'librsvg' 'libgudev')
-source=(https://download.handbrake.fr/releases/$pkgver/HandBrake-$pkgver-source.tar.bz2
-        https://github.com/HandBrake/HandBrake/releases/download/$pkgver/HandBrake-$pkgver-source.tar.bz2.sig)
-sha256sums=('df6816f517d60ae8a6626aa731821af2d1966c155fa53b2b9a06c47f3c565e4c'
-            'SKIP')
-validpgpkeys+=('1629C061B3DDE7EB4AE34B81021DB8B44E4A8645') # HandBrake Team <developers at handbrake.fr>
-
-build() {
-  cd "$srcdir/HandBrake-$pkgver"
-
-  ./configure --prefix=/usr
-  make -C build
-}
-
-package_handbrake() {
-  pkgdesc="Multithreaded video transcoder"
-  depends=('bzip2' 'gcc-libs' 'zlib' 'gst-plugins-base' 'libnotify' 'dbus-glib'
-           'gtk3' 'xz' 'libass' 'lame' 'libxml2' 'opus' 'libvorbis' 'libtheora'
-           'libsamplerate' 'speex' 'x264' 'jansson' 'librsvg' 'libgudev'
-           'desktop-file-utils' 'hicolor-icon-theme')
-  optdepends=('gst-plugins-good: for video previews'
-              'gst-libav: for video previews'
-              'libdvdcss: for decoding encrypted DVDs')
-
-  cd "$srcdir/HandBrake-$pkgver/build"
-
-  make DESTDIR="$pkgdir" install
-  rm "$pkgdir/usr/bin/HandBrakeCLI"
-}
-
-package_handbrake-cli() {
-  pkgdesc="Multithreaded video transcoder (CLI)"
-  depends=('bzip2' 'gcc-libs' 'zlib' 'xz' 'libass' 'lame' 'libxml2' 'opus'
-           'libvorbis' 'libtheora' 'libsamplerate' 'speex' 'x264' 'jansson')
-  optdepends=('libdvdcss: for decoding encrypted DVDs')
-
-  cd "$srcdir/HandBrake-$pkgver/build"
-  install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
-}
-
-# vim:set ts=2 sw=2 et:

Copied: handbrake/repos/community-x86_64/PKGBUILD (from rev 526601, handbrake/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-11-11 00:23:39 UTC (rev 526602)
@@ -0,0 +1,54 @@
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Sebastien Piccand <sebcactus gmail com>
+
+pkgname=('handbrake' 'handbrake-cli')
+pkgver=1.3.0
+pkgrel=1
+arch=('x86_64')
+url="https://handbrake.fr/"
+license=('GPL')
+_commondeps=('libxml2' 'libass' 'libvorbis' 'opus' 'speex' 'libtheora' 'lame'
+             'x264' 'jansson' 'libvpx' 'libva' 'numactl'
+             'bzip2' 'gcc-libs' 'zlib' 'xz')
+_guideps=('gst-plugins-base' 'gtk3' 'librsvg' 'libgudev')
+makedepends=('intltool' 'python' 'nasm' 'wget' 'cmake' 'meson'
+             "${_commondeps[@]}" "${_guideps[@]}")
+source=(https://download.handbrake.fr/releases/$pkgver/HandBrake-$pkgver-source.tar.bz2{,.sig})
+sha256sums=('a9a82eb5ca04a793705b3d7d11cefa29946694eeb13b40161446aaca35b31d96'
+            'SKIP')
+validpgpkeys+=('1629C061B3DDE7EB4AE34B81021DB8B44E4A8645') # HandBrake Team <developers at handbrake.fr>
+
+build() {
+  cd "$srcdir/HandBrake-$pkgver"
+
+  ./configure \
+    --prefix=/usr \
+    --enable-qsv
+  make -C build
+}
+
+package_handbrake() {
+  pkgdesc="Multithreaded video transcoder"
+  depends=('desktop-file-utils' 'hicolor-icon-theme'
+           "${_commondeps[@]}" "${_guideps[@]}")
+  optdepends=('gst-plugins-good: for video previews'
+              'gst-libav: for video previews'
+              'libdvdcss: for decoding encrypted DVDs')
+
+  cd "$srcdir/HandBrake-$pkgver/build"
+
+  make DESTDIR="$pkgdir" install
+  rm "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+package_handbrake-cli() {
+  pkgdesc="Multithreaded video transcoder (CLI)"
+  depends=("${_commondeps[@]}")
+  optdepends=('libdvdcss: for decoding encrypted DVDs')
+
+  cd "$srcdir/HandBrake-$pkgver/build"
+  install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+# vim:set ts=2 sw=2 et: