[arch-commits] Commit in json-c/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Felix Yan
felixonmars at archlinux.org
Wed Nov 13 16:00:53 UTC 2019
Date: Wednesday, November 13, 2019 @ 16:00:52
Author: felixonmars
Revision: 368143
archrelease: copy trunk to staging-x86_64
Added:
json-c/repos/staging-x86_64/
json-c/repos/staging-x86_64/PKGBUILD
(from rev 368142, json-c/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: json-c/repos/staging-x86_64/PKGBUILD (from rev 368142, json-c/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2019-11-13 16:00:52 UTC (rev 368143)
@@ -0,0 +1,50 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Geoffroy Carrier <geoffroy.carrier at koon.fr>
+# Contributor: congyiwu <congyiwu AT gmail DOT com>
+
+pkgname=json-c
+pkgver=0.13.1
+pkgrel=3
+pkgdesc="A JSON implementation in C"
+url="https://github.com/json-c/json-c/wiki"
+license=(MIT)
+arch=(x86_64)
+depends=(glibc)
+makedepends=(git)
+_commit=985c46fec39d1d3043f98e8d8cdb9d040131b3bb # tags/json-c-0.13.1-20180305^0
+source=("git+https://github.com/json-c/json-c#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd json-c
+ local tag="$(git describe --tags --abbrev=0)"
+ local ver="$(git describe --tags)"
+ echo "${tag%-*}${ver#$tag}" | sed 's/^json-c-//;s/-/+/g'
+}
+
+prepare() {
+ cd json-c
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd json-c
+ ./configure \
+ --prefix=/usr \
+ --disable-static \
+ --enable-threading
+ make
+}
+
+check() {
+ cd json-c
+ make check
+}
+
+package() {
+ cd json-c
+ make DESTDIR="$pkgdir" install
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
+}
+
+# vim:set sw=2 et:
More information about the arch-commits
mailing list