[arch-commits] Commit in libopenshot/trunk (PKGBUILD)

[David Runge]

    Date: Thursday, November 14, 2019 @ 08:38:35
  Author: dvzrv
Revision: 527203

upgpkg: libopenshot 0.2.3-5

Updating maintainer info. 'Fixing' a braindead cmake module for finding python3 libs and headers (FS#64463).
Renaming upstream patch, so one actually knows why it is there. Running tests in check(). Adding all direct library dependencies and adding libopenshot.so to provides. Minor fixes.

Modified:
  libopenshot/trunk/PKGBUILD

----------+
 PKGBUILD |   53 ++++++++++++++++++++++++++++++++++++-----------------
 1 file changed, 36 insertions(+), 17 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2019-11-13 22:49:35 UTC (rev 527202)
+++ PKGBUILD	2019-11-14 08:38:35 UTC (rev 527203)
@@ -1,38 +1,57 @@
-# Maintainer : Martin Wimpress <code at flexion.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Martin Wimpress <code at flexion.org>
 # Contributor: Foster McLane <fkmclane at gmail.com>
 # Contributor: Jonathan Thomas <jonathan at openshot.org>
 
 pkgname=libopenshot
 pkgver=0.2.3
-pkgrel=4
-pkgdesc="A high quality, open-source video editing, animation, and playback library for C++, Python, and Ruby."
+pkgrel=5
+pkgdesc="A video editing, animation, and playback library for C++, Python, and Ruby"
 arch=('x86_64')
 url="https://openshot.org/"
 license=('LGPL3')
-depends=('libmagick6' 'ffmpeg' 'x264' 'libopenshot-audio' 'python' 'libjsoncpp.so' 'qt5-multimedia' 'zeromq')
+depends=('gcc-libs' 'glibc' 'libavcodec.so' 'libavformat.so' 'libavutil.so'
+'libswscale.so' 'libswresample.so' 'libmagick6' 'libopenshot-audio' 'python'
+'libjsoncpp.so' 'qt5-base' 'qt5-multimedia' 'x264' 'zeromq')
 makedepends=('cmake' 'doxygen' 'swig' 'unittestpp')
+provides=('libopenshot.so')
 source=("$pkgname-$pkgver.tar.gz::https://github.com/OpenShot/libopenshot/archive/v$pkgver.tar.gz"
-        "$pkgname-pr-209.patch::https://github.com/OpenShot/libopenshot/pull/209.patch")
+        "$pkgname-find-juce.patch::https://github.com/OpenShot/libopenshot/pull/209.patch")
 sha256sums=('8536b0a790b0d98ed4c3b10e11d1b34ae68ccbc710887e3703a5143d95598746'
             '038b945763dc035ecffe0968a9f0f7a29bb86a3919f4192901d5f152eb5c7f89')
 
 prepare() {
-	cd ${pkgname}-${pkgver}
-
-	patch -p1 -i "$srcdir/$pkgname-pr-209.patch"
+  cd "${pkgname}-${pkgver}"
+  patch -p1 -i "../${pkgname}-find-juce.patch"
+  # fix hardcoded cmake module to find python3.8:
+  # https://bugs.archlinux.org/task/64463
+  sed -e 's/3.7/3.7 3.8/' \
+      -i cmake/Modules/FindPythonLibs.cmake
+  mkdir -vp build
 }
 
 build() {
-	cd ${pkgname}-${pkgver}
-	mkdir build
-	cd build
-	cmake -DCMAKE_INSTALL_PREFIX:PATH=/usr -DMAGICKCORE_HDRI_ENABLE=1 -DMAGICKCORE_QUANTUM_DEPTH=16 \
-	      -DUSE_SYSTEM_JSONCPP=ON -DENABLE_RUBY=OFF ../
-	make
+  cd "${pkgname}-${pkgver}"
+  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+  export PYTHON_LIBRARIES="/usr/lib/libpython3.so"
+  export PYTHON_INCLUDE_DIRS="/usr/include/python${python_version}"
+  cmake -DCMAKE_INSTALL_PREFIX=/usr \
+        -DMAGICKCORE_HDRI_ENABLE=1 \
+        -DMAGICKCORE_QUANTUM_DEPTH=16 \
+        -DUSE_SYSTEM_JSONCPP=ON \
+        -DPYTHON_LIBRARIES="/usr/lib/libpython3.so" \
+        -DPYTHON_INCLUDE_DIRS="/usr/include/python${python_version}" \
+        -DENABLE_RUBY=OFF \
+        -B build
+  make -C build
 }
 
+check() {
+  cd "${pkgname}-${pkgver}"
+  make -C build test
+}
+
 package() {
-	cd ${pkgname}-${pkgver}
-	cd build
-	make DESTDIR="${pkgdir}" install
+  cd "${pkgname}-${pkgver}"
+  make -C build DESTDIR="${pkgdir}" install
 }