[arch-commits] Commit in haskell-bytestring-tree-builder/repos (2 files)

[Felix Yan]

    Date: Thursday, November 21, 2019 @ 19:44:38
  Author: felixonmars
Revision: 531216

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-bytestring-tree-builder/repos/community-staging-x86_64/
  haskell-bytestring-tree-builder/repos/community-staging-x86_64/PKGBUILD
    (from rev 531215, haskell-bytestring-tree-builder/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-bytestring-tree-builder/repos/community-staging-x86_64/PKGBUILD (from rev 531215, haskell-bytestring-tree-builder/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-11-21 19:44:38 UTC (rev 531216)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=bytestring-tree-builder
+pkgname=haskell-bytestring-tree-builder
+pkgver=0.2.7.3
+pkgrel=18
+pkgdesc="A very efficient ByteString builder implementation based on the binary tree"
+url="https://github.com/nikita-volkov/bytestring-tree-builder"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-prelude')
+makedepends=('ghc' 'haskell-tasty' 'haskell-tasty-quickcheck' 'haskell-tasty-hunit'
+             'haskell-quickcheck-instances' 'haskell-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('dc23685313cbe97084c63954b167375aac481019b657db5e936ff4c5c210160407ad8305b6ec15e31890eba3187f5a3aaaef1a27d54b9a0cfe30ec694442afb2')
+
+prepare() {
+    cd $_hkgname-$pkgver
+
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}