[arch-commits] Commit in lib32-libxslt/repos (2 files)
Antonio Rojas
arojas at archlinux.org
Thu Nov 21 21:23:53 UTC 2019
Date: Thursday, November 21, 2019 @ 21:23:52
Author: arojas
Revision: 531342
archrelease: copy trunk to multilib-testing-x86_64
Added:
lib32-libxslt/repos/multilib-testing-x86_64/
lib32-libxslt/repos/multilib-testing-x86_64/PKGBUILD
(from rev 531341, lib32-libxslt/trunk/PKGBUILD)
----------+
PKGBUILD | 48 ++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 48 insertions(+)
Copied: lib32-libxslt/repos/multilib-testing-x86_64/PKGBUILD (from rev 531341, lib32-libxslt/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD (rev 0)
+++ multilib-testing-x86_64/PKGBUILD 2019-11-21 21:23:52 UTC (rev 531342)
@@ -0,0 +1,48 @@
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+_pkgbasename=libxslt
+pkgname=lib32-libxslt
+pkgver=1.1.34
+pkgrel=1
+pkgdesc="XML stylesheet transformation library (32-bit)"
+arch=('x86_64')
+url="http://xmlsoft.org/XSLT/"
+license=('custom')
+depends=('lib32-libxml2' 'lib32-libgcrypt' 'libxslt' 'lib32-xz')
+makedepends=(gcc-multilib git)
+_commit=3653123f992db24cec417d12600f4c67388025e3 # tags/v1.1.34^0
+source=("git+https://gitlab.gnome.org/GNOME/libxslt.git#commit=$_commit")
+md5sums=('SKIP')
+
+pkgver() {
+ cd "${_pkgbasename}"
+ git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+ cd "${_pkgbasename}"
+
+ sed -e 's|/usr/bin/python -u|/usr/bin/python2 -u|g' -e 's|/usr/bin/python$|/usr/bin/python2|g' -i python/tests/*.py
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+ cd "${_pkgbasename}"
+ ./configure --prefix=/usr --libdir=/usr/lib32 --without-python
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+package() {
+ cd "${_pkgbasename}"
+ make DESTDIR="${pkgdir}" install
+
+ install -d "${pkgdir}"/usr/share/licenses
+ ln -s ${_pkgbasename} "${pkgdir}"/usr/share/licenses/${pkgname}
+
+ rm -rf "${pkgdir}"/usr/{include,share,bin}
+ rm -f "${pkgdir}"/usr/lib/python*/site-packages/*.a
+}
More information about the arch-commits
mailing list