[arch-commits] Commit in (4 files)

[Anatol Pomozov]

    Date: Sunday, November 24, 2019 @ 19:21:27
  Author: anatolik
Revision: 533089

Add aws-c-common C library

Added:
  aws-c-common/
  aws-c-common/repos/
  aws-c-common/trunk/
  aws-c-common/trunk/PKGBUILD

----------+
 PKGBUILD |   31 +++++++++++++++++++++++++++++++
 1 file changed, 31 insertions(+)

Added: aws-c-common/trunk/PKGBUILD
===================================================================
--- aws-c-common/trunk/PKGBUILD	                        (rev 0)
+++ aws-c-common/trunk/PKGBUILD	2019-11-24 19:21:27 UTC (rev 533089)
@@ -0,0 +1,31 @@
+# Maintainer: Anatol Pomozov
+
+pkgname=aws-c-common
+pkgver=0.4.22
+pkgrel=1
+pkgdesc='Core c99 package for AWS SDK for C. Includes cross-platform primitives, configuration, data structures, and error handling.'
+arch=(x86_64)
+url='https://github.com/awslabs/aws-c-common'
+license=(Apache)
+depends=(cmake)
+source=(aws-c-common-$pkgver.zip::https://github.com/awslabs/aws-c-common/archive/v$pkgver.zip)
+sha256sums=('39f99419e2aa0fcb59872067f9e9e04fbd5f6bbdf9ee8041874ff89d24f152ca')
+
+build() {
+  cd aws-c-common-$pkgver
+
+  cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr -DBUILD_SHARED_LIBS=ON -S . -B build
+  cmake --build build
+}
+
+check() {
+  cd aws-c-common-$pkgver
+  cmake --build build --target test
+}
+
+package() {
+  cd aws-c-common-$pkgver
+
+  cmake --build build --target install -- DESTDIR="$pkgdir/"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}


Property changes on: aws-c-common/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property